Change in osmo-ttcn3-hacks[master]: bts: Introduce test TC_tx_power_start_ramp_down_bcch

[pespin]

pespin has uploaded this change for review. ( https://gerrit.osmocom.org/c/osmo-ttcn3-hacks/+/18980 )


Change subject: bts: Introduce test TC_tx_power_start_ramp_down_bcch
......................................................................

bts: Introduce test TC_tx_power_start_ramp_down_bcch

Change-Id: I895d69394a0123ae32b336c9ffaff615ba657f12
---
M bts/BTS_Tests.ttcn
1 file changed, 95 insertions(+), 0 deletions(-)



  git pull ssh://gerrit.osmocom.org:29418/osmo-ttcn3-hacks refs/changes/80/18980/1

diff --git a/bts/BTS_Tests.ttcn b/bts/BTS_Tests.ttcn
index 9ebd952..38521c6 100644
--- a/bts/BTS_Tests.ttcn
+++ b/bts/BTS_Tests.ttcn
@@ -173,6 +173,9 @@
 	port TRXC_CODEC_PT BTS_TRXC;
 	var integer g_bts_trxc_conn_id;
 
+	/* port to be initialized optionally to access BSC VTY */
+	port TELNETasp_PT BSCVTY;
+
 	timer g_Tguard;
 	timer g_Tmeas_exp := 2.0; /* >= 103 SACCH multiframe ~ 500ms */
 
@@ -2101,6 +2104,97 @@
 	Misc_Helpers.f_shutdown(__BFILE__, __LINE__);
 }
 
+/* Verify Tx power reduction and ramping downd uring BTS bring shutdown due to Abis link failure */
+function f_TC_tx_power_start_ramp_down_bcch(charstring id) runs on ConnHdlr {
+	var L1ctlDlMessage l1_dl;
+
+	map(self:BSCVTY, system:BSCVTY);
+	f_vty_set_prompts(BSCVTY, "OsmoBSC");
+	f_vty_transceive(BSCVTY, "enable");
+
+	f_l1_tune(L1CTL);
+	RSL.clear;
+
+	var integer last_rx_lvl;
+	var integer max_rx_lvl := mp_bts_tx_nom_pwr_exp - mp_bts_tx_pwr_att_exp;
+
+	/* Wait until BTS is started and at full power */
+	timer Tup := 10.0;
+	Tup.start;
+	alt {
+	[] L1CTL.receive(tr_L1CTL_DATA_IND(t_RslChanNr_BCCH(0), ?)) -> value l1_dl {
+		var GsmRxLev rx_lvl := l1_dl.dl_info.rx_level;
+		log("Received rx_level=", rx_lvl);
+
+		if (rx_lvl != max_rx_lvl) {
+			repeat;
+		}
+		log("Reached nominal level ", max_rx_lvl, ", shutting down OML link");
+		Tup.stop;
+		}
+	[] L1CTL.receive { repeat; }
+	[] Tup.timeout {
+		Misc_Helpers.f_shutdown(__BFILE__, __LINE__, fail,
+					log2str("Didn't reach full power ", max_rx_lvl));
+		}
+	}
+
+	f_vty_transceive(BSCVTY, "drop bts connection 0 oml");
+	last_rx_lvl := max_rx_lvl;
+	timer Tdown := 5.0;
+	Tdown.start;
+	alt {
+	[] L1CTL.receive(tr_L1CTL_DATA_IND(t_RslChanNr_BCCH(0), ?)) -> value l1_dl {
+		var GsmRxLev rx_lvl := l1_dl.dl_info.rx_level;
+		log("Received rx_level=", rx_lvl);
+
+		/* received Rx level bigger than maximum allowed power by CN */
+		if (rx_lvl > max_rx_lvl) {
+			Misc_Helpers.f_shutdown(__BFILE__, __LINE__, fail,
+						log2str("Detected Tx power higher than full power: ",
+							rx_lvl , " > ", max_rx_lvl));
+		}
+
+		/* Make sure it never increases, since we are rumping down */
+		if (last_rx_lvl < rx_lvl) {
+			Misc_Helpers.f_shutdown(__BFILE__, __LINE__, fail,
+						log2str("Detected Tx power increase during ramp up: ",
+							last_rx_lvl , " -> ", rx_lvl));
+		}
+
+		last_rx_lvl := rx_lvl;
+		if (last_rx_lvl != 0) {
+			repeat;
+		}
+		/* we reached power level 0, we are done */
+		Tdown.stop;
+		}
+	[] L1CTL.receive { repeat; }
+	[] Tdown.timeout { }
+	}
+
+	/* We didn't increase tx power during ramp up */
+	if (max_rx_lvl > last_rx_lvl) {
+		log("Tx power decreased during ramp down: ", max_rx_lvl , " -> ", last_rx_lvl);
+	} else {
+		Misc_Helpers.f_shutdown(__BFILE__, __LINE__, fail,
+					log2str("No Tx power decrease during whole ramp down: ",
+						max_rx_lvl , " -> ", last_rx_lvl));
+	}
+
+	setverdict(pass);
+}
+testcase TC_tx_power_start_ramp_down_bcch() runs on test_CT {
+	var ConnHdlr vc_conn;
+	var ConnHdlrPars pars;
+	f_init();
+	pars := valueof(t_Pars(t_RslChanNr_Bm(0), ts_RSL_ChanMode_SIGN));
+	vc_conn := f_start_handler(refers(f_TC_tx_power_start_ramp_down_bcch), pars,
+				   pcu_comp := false, trxc_comp := true);
+	vc_conn.done;
+	Misc_Helpers.f_shutdown(__BFILE__, __LINE__);
+}
+
 function f_check_meas_bs_power_level(integer level) runs on ConnHdlr {
 	timer T := 8.0;
 	T.start;
@@ -6519,6 +6613,7 @@
 	execute( TC_meas_res_sign_sdcch8() );
 	execute( TC_meas_res_sign_tchh_toa256() );
 	execute( TC_tx_power_start_ramp_up_bcch() );
+	execute( TC_tx_power_start_ramp_down_bcch() );
 	execute( TC_rsl_bs_pwr_static_ass() );
 	execute( TC_rsl_bs_pwr_static_power_control() );
 	execute( TC_rsl_ms_pwr_ctrl() );

-- 
To view, visit https://gerrit.osmocom.org/c/osmo-ttcn3-hacks/+/18980
To unsubscribe, or for help writing mail filters, visit https://gerrit.osmocom.org/settings

Gerrit-Project: osmo-ttcn3-hacks
Gerrit-Branch: master
Gerrit-Change-Id: I895d69394a0123ae32b336c9ffaff615ba657f12
Gerrit-Change-Number: 18980
Gerrit-PatchSet: 1
Gerrit-Owner: pespin <pespin at sysmocom.de>
Gerrit-MessageType: newchange
-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://lists.osmocom.org/pipermail/gerrit-log/attachments/20200623/aacb147a/attachment.htm>