pespin has uploaded this change for review.
Introduce nrf testsuite
Add the testsite with multiple sample tests, so that it can be extended
easily in the future with more.
Related: SYS#7073
Change-Id: Ibe60a996685c6c08443ad9209c33b5961aef4b1f
---
M Makefile
M library/TS29510_Nnrf_NFManagement_Templates.ttcn
A nrf/ConnHdlr.ttcn
A nrf/NRF_Tests.cfg
A nrf/NRF_Tests.default
A nrf/NRF_Tests.ttcn
A nrf/README.md
A nrf/expected-results.xml
A nrf/gen_links.sh
A nrf/open5gs-nrf.yaml
A nrf/regen_makefile.sh
A nrf/testenv.cfg
A nrf/testsrcdir.cfg
13 files changed, 933 insertions(+), 0 deletions(-)
git pull ssh://gerrit.osmocom.org:29418/osmo-ttcn3-hacks refs/changes/52/44152/1
diff --git a/Makefile b/Makefile
index 3baeddd..40bbe2c 100644
--- a/Makefile
+++ b/Makefile
@@ -41,6 +41,7 @@
mgw \
mme \
msc \
+ nrf \
ns \
nssf \
pcap-client \
diff --git a/library/TS29510_Nnrf_NFManagement_Templates.ttcn b/library/TS29510_Nnrf_NFManagement_Templates.ttcn
index 4175f77..b709285 100644
--- a/library/TS29510_Nnrf_NFManagement_Templates.ttcn
+++ b/library/TS29510_Nnrf_NFManagement_Templates.ttcn
@@ -14,6 +14,16 @@
template (value) charstring ts_Nnrf_NFM_path_nf_instance(template (value) charstring nf_instance_id)
:= c_Nnrf_NFM_path_nf_instances & "/" & valueof(nf_instance_id);
+template (value) NFType1
+ts_NFType1(template (value) NFType1_enum enum_val) := {
+ enum_val := enum_val
+}
+
+template (value) NFStatus1
+ts_NFStatus1(template (value) NFStatus1_enum enum_val) := {
+ enum_val := enum_val
+}
+
template (value) PlmnId1
ts_PlmnId1(template (value) Mcc1 mcc,
template (value) Mnc1 mnc) := {
@@ -21,6 +31,22 @@
mnc := mnc
}
+template (value) PlmnIdNid1
+ts_PlmnIdNid1(template (value) Mcc mcc,
+ template (value) Mnc mnc,
+ template (omit) Nid nid := omit) := {
+ mcc := mcc,
+ mnc := mnc,
+ nid := nid
+}
+
+template (value) Guami1
+ts_Guami1(template (value) PlmnIdNid1 plmnId,
+ template (value) AmfId amfId) := {
+ plmnId := plmnId,
+ amfId := amfId
+}
+
template (value) Link1
ts_Link1(template (omit) Uri href := omit) := {
href := href
@@ -39,6 +65,50 @@
totalItemCount := totalItemCount
}
+template (value) PatchOperation1
+ts_PatchOperation1(template (value) PatchOperation1_enum enum_val) := {
+ enum_val := enum_val
+}
+
+template (value) PatchItem1
+ts_PatchItem1(template (value) PatchOperation1 op,
+ template (value) charstring path,
+ template (omit) charstring from_ := omit,
+ template (omit) JSON_Generic.JSON_generic_val value_ := omit) := {
+ op := op,
+ path := path,
+ from_ := from_,
+ value_ := value_
+}
+
+template (value) AmfInfo1
+ts_AmfInfo1 (template (value) AmfSetId1 amfSetId,
+ template (value) AmfRegionId1 amfRegionId,
+ template (value) TS29510_Nnrf_NFManagement.AmfInfo1.guamiList guamiList,
+ template (omit) TS29510_Nnrf_NFManagement.AmfInfo1.taiList taiList := omit,
+ template (omit) TS29510_Nnrf_NFManagement.AmfInfo1.taiRangeList taiRangeList := omit,
+ template (omit) TS29510_Nnrf_NFManagement.AmfInfo1.backupInfoAmfFailure backupInfoAmfFailure := omit,
+ template (omit) TS29510_Nnrf_NFManagement.AmfInfo1.backupInfoAmfRemoval backupInfoAmfRemoval := omit,
+ template (omit) N2InterfaceAmfInfo1 n2InterfaceAmfInfo := omit,
+ template (omit) boolean amfOnboardingCapability := omit,
+ template (omit) boolean highLatencyCom := omit,
+ template (omit) TS29510_Nnrf_NFManagement.AmfInfo1.amfEvents amfEvents := omit,
+ template (omit) record of charstring praIdList := omit,
+ template (omit) TS29510_Nnrf_NFManagement.AmfInfo1.mobileIabInd mobileIabInd := omit) := {
+ amfSetId := amfSetId,
+ amfRegionId := amfRegionId,
+ guamiList := guamiList,
+ taiList := taiList,
+ taiRangeList := taiRangeList,
+ backupInfoAmfFailure := backupInfoAmfFailure,
+ backupInfoAmfRemoval := backupInfoAmfRemoval,
+ n2InterfaceAmfInfo := n2InterfaceAmfInfo,
+ amfOnboardingCapability := amfOnboardingCapability,
+ highLatencyCom := highLatencyCom,
+ amfEvents := amfEvents,
+ praIdList := praIdList,
+ mobileIabInd := mobileIabInd
+}
type TS29510_Nnrf_NFManagement.NFProfile1.collocatedNfInstances CollocatedNfInstancesList;
type TS29510_Nnrf_NFManagement.NFProfile1.plmnList PlmnList;
@@ -302,4 +372,219 @@
admInfo := admInfo
}
+template (value) NFProfile1
+ts_NFProfile1(template (value) NfInstanceId1 nfInstanceId,
+ template (omit) charstring nfInstanceName := omit,
+ template (value) NFType1 nfType,
+ template (value) NFStatus1 nfStatus,
+ template (omit) CollocatedNfInstancesList collocatedNfInstances := omit,
+ template (omit) integer heartBeatTimer := omit,
+ template (omit) PlmnList plmnList := omit,
+ template (omit) SnpnList snpnList := omit,
+ template (omit) SNssaisList sNssais := omit,
+ template (omit) PerPlmnSnssaiList perPlmnSnssaiList := omit,
+ template (omit) record of charstring nsiList := omit,
+ template (omit) Fqdn1 fqdn := omit,
+ template (omit) Fqdn1 interPlmnFqdn := omit,
+ template (omit) Ipv4Addr1List ipv4Addresses := omit,
+ template (omit) Ipv6Addresses ipv6Addresses := omit,
+ template (omit) AllowedPlmnsList allowedPlmns := omit,
+ template (omit) AllowedSnpnsList allowedSnpns := omit,
+ template (omit) AllowedNfTypes allowedNfTypes := omit,
+ template (omit) record of charstring allowedNfDomains := omit,
+ template (omit) AllowedNssais allowedNssais := omit,
+ template (omit) AllowedRuleSet allowedRuleSet := omit,
+ template (omit) integer priority := omit,
+ template (omit) integer capacity := omit,
+ template (omit) integer load := omit,
+ template (omit) DateTime2 loadTimeStamp := omit,
+ template (omit) charstring locality := omit,
+ template (omit) ExtLocalityMap extLocality := omit,
+ template (omit) UdrInfo1 udrInfo := omit,
+ template (omit) UdrInfoListMap udrInfoList := omit,
+ template (omit) UdmInfo1 udmInfo := omit,
+ template (omit) UdmInfoListMap udmInfoList := omit,
+ template (omit) AusfInfo1 ausfInfo := omit,
+ template (omit) AusfInfoListMap ausfInfoList := omit,
+ template (omit) AmfInfo1 amfInfo := omit,
+ template (omit) AmfInfoListMap amfInfoList := omit,
+ template (omit) SmfInfo1 smfInfo := omit,
+ template (omit) SmfInfoListMap smfInfoList := omit,
+ template (omit) UpfInfo1 upfInfo := omit,
+ template (omit) UpfInfoListMap upfInfoList := omit,
+ template (omit) PcfInfo1 pcfInfo := omit,
+ template (omit) PcfInfoListMap pcfInfoList := omit,
+ template (omit) BsfInfo1 bsfInfo := omit,
+ template (omit) BsfInfoListMap bsfInfoList := omit,
+ template (omit) ChfInfo1 chfInfo := omit,
+ template (omit) ChfInfoListMap chfInfoList := omit,
+ template (omit) NefInfo1 nefInfo := omit,
+ template (omit) NrfInfo1 nrfInfo := omit,
+ template (omit) UdsfInfo1 udsfInfo := omit,
+ template (omit) UdsfInfoListMap udsfInfoList := omit,
+ template (omit) NwdafInfo1 nwdafInfo := omit,
+ template (omit) NwdaInfoListMap nwdafInfoList := omit,
+ template (omit) PcscfInfoListMap pcscfInfoList := omit,
+ template (omit) HssInfoListMap hssInfoList := omit,
+ template (omit) JSON_Generic.JSON_generic_val customInfo := omit,
+ template (omit) DateTime2 recoveryTime := omit,
+ template (omit) boolean nfServicePersistence := omit,
+ template (omit) NFService1List nfServices := omit,
+ template (omit) NfServiceListMap nfServiceList := omit,
+ template (omit) boolean nfProfileChangesSupportInd := omit,
+ template (omit) boolean nfProfilePartialUpdateChangesSupportInd := omit,
+ template (omit) boolean nfProfileChangesInd := omit,
+ template (omit) DefaultNotificationSubscription1List defaultNotificationSubscriptions := omit,
+ template (omit) LmfInfo1 lmfInfo := omit,
+ template (omit) GmlcInfo1 gmlcInfo := omit,
+ template (omit) NfSetIdList nfSetIdList := omit,
+ template (omit) record of charstring servingScope := omit,
+ template (omit) boolean lcHSupportInd := omit,
+ template (omit) boolean olcHSupportInd := omit,
+ template (omit) NfSetRecoveryTimeListMap nfSetRecoveryTimeList := omit,
+ template (omit) ServiceSetRecoveryTimeListMap serviceSetRecoveryTimeList := omit,
+ template (omit) record of charstring scpDomains := omit,
+ template (omit) ScpInfo1 scpInfo := omit,
+ template (omit) SeppInfo1 seppInfo := omit,
+ template (omit) VendorId1 vendorId := omit,
+ template (omit) SupportedVendorSpecificFeatures supportedVendorSpecificFeatures := omit,
+ template (omit) AanfInfoListMap aanfInfoList := omit,
+ template (omit) FiveGDdnmfInfo1 fivegDdnmfInfo := omit,
+ template (omit) MfafInfo1 mfafInfo := omit,
+ template (omit) EasdfInfoListMap easdfInfoList := omit,
+ template (omit) DccfInfo1 dccfInfo := omit,
+ template (omit) NsacfInfoListMap nsacfInfoList := omit,
+ template (omit) MbSmfInfoListMap mbSmfInfoList := omit,
+ template (omit) TsctsfInfoListMap tsctsfInfoList := omit,
+ template (omit) MbUpfInfoListMap mbUpfInfoList := omit,
+ template (omit) TrustAfInfo1 trustAfInfo := omit,
+ template (omit) NssaafInfo1 nssaafInfo := omit,
+ template (omit) HniList hniList := omit,
+ template (omit) IwmscInfo1 iwmscInfo := omit,
+ template (omit) MnpfInfo1 mnpfInfo := omit,
+ template (omit) SmsfInfo1 smsfInfo := omit,
+ template (omit) DcsfInfoListMap dcsfInfoList := omit,
+ template (omit) MrfInfoListMap mrfInfoList := omit,
+ template (omit) MrfpInfoListMap mrfpInfoList := omit,
+ template (omit) MfInfoListMap mfInfoList := omit,
+ template (omit) AdrfInfoListMap adrfInfoList := omit,
+ template (omit) SelectionConditions1 selectionConditions := omit,
+ template (omit) boolean canaryRelease := omit,
+ template (omit) boolean exclusiveCanaryReleaseSelection := omit,
+ template (omit) charstring sharedProfileDataId := omit,
+ template (omit) DateTime2 shutdownTime := omit,
+ template (omit) SupportedRcfsList supportedRcfs := omit,
+ template (omit) boolean canaryPrecedenceOverPreferred := omit,
+ template (omit) ImsasInfo1 imsasInfo := omit,
+ template (omit) AiotfInfoListMap aiotfInfoList := omit,
+ template (omit) NssfInfo1 nssfInfo := omit,
+ template (omit) AdmInfo1 admInfo := omit) := {
+ nfInstanceId := nfInstanceId,
+ nfInstanceName := nfInstanceName,
+ nfType := nfType,
+ nfStatus := nfStatus,
+ collocatedNfInstances := collocatedNfInstances,
+ heartBeatTimer := heartBeatTimer,
+ plmnList := plmnList,
+ snpnList := snpnList,
+ sNssais := sNssais,
+ perPlmnSnssaiList := perPlmnSnssaiList,
+ nsiList := nsiList,
+ fqdn := fqdn,
+ interPlmnFqdn := interPlmnFqdn,
+ ipv4Addresses := ipv4Addresses,
+ ipv6Addresses := ipv6Addresses,
+ allowedPlmns := allowedPlmns,
+ allowedSnpns := allowedSnpns,
+ allowedNfTypes := allowedNfTypes,
+ allowedNfDomains := allowedNfDomains,
+ allowedNssais := allowedNssais,
+ allowedRuleSet := allowedRuleSet,
+ priority := priority,
+ capacity := capacity,
+ load := load,
+ loadTimeStamp := loadTimeStamp,
+ locality := locality,
+ extLocality := extLocality,
+ udrInfo := udrInfo,
+ udrInfoList := udrInfoList,
+ udmInfo := udmInfo,
+ udmInfoList := udmInfoList,
+ ausfInfo := ausfInfo,
+ ausfInfoList := ausfInfoList,
+ amfInfo := amfInfo,
+ amfInfoList := amfInfoList,
+ smfInfo := smfInfo,
+ smfInfoList := smfInfoList,
+ upfInfo := upfInfo,
+ upfInfoList := upfInfoList,
+ pcfInfo := pcfInfo,
+ pcfInfoList := pcfInfoList,
+ bsfInfo := bsfInfo,
+ bsfInfoList := bsfInfoList,
+ chfInfo := chfInfo,
+ chfInfoList := chfInfoList,
+ nefInfo := nefInfo,
+ nrfInfo := nrfInfo,
+ udsfInfo := udsfInfo,
+ udsfInfoList := udsfInfoList,
+ nwdafInfo := nwdafInfo,
+ nwdafInfoList := nwdafInfoList,
+ pcscfInfoList := pcscfInfoList,
+ hssInfoList := hssInfoList,
+ customInfo := customInfo,
+ recoveryTime := recoveryTime,
+ nfServicePersistence := nfServicePersistence,
+ nfServices := nfServices,
+ nfServiceList := nfServiceList,
+ nfProfileChangesSupportInd := nfProfileChangesSupportInd,
+ nfProfilePartialUpdateChangesSupportInd := nfProfilePartialUpdateChangesSupportInd,
+ nfProfileChangesInd := nfProfileChangesInd,
+ defaultNotificationSubscriptions := defaultNotificationSubscriptions,
+ lmfInfo := lmfInfo,
+ gmlcInfo := gmlcInfo,
+ nfSetIdList := nfSetIdList,
+ servingScope := servingScope,
+ lcHSupportInd := lcHSupportInd,
+ olcHSupportInd := olcHSupportInd,
+ nfSetRecoveryTimeList := nfSetRecoveryTimeList,
+ serviceSetRecoveryTimeList := serviceSetRecoveryTimeList,
+ scpDomains := scpDomains,
+ scpInfo := scpInfo,
+ seppInfo := seppInfo,
+ vendorId := vendorId,
+ supportedVendorSpecificFeatures := supportedVendorSpecificFeatures,
+ aanfInfoList := aanfInfoList,
+ fivegDdnmfInfo := fivegDdnmfInfo,
+ mfafInfo := mfafInfo,
+ easdfInfoList := easdfInfoList,
+ dccfInfo := dccfInfo,
+ nsacfInfoList := nsacfInfoList,
+ mbSmfInfoList := mbSmfInfoList,
+ tsctsfInfoList := tsctsfInfoList,
+ mbUpfInfoList := mbUpfInfoList,
+ trustAfInfo := trustAfInfo,
+ nssaafInfo := nssaafInfo,
+ hniList := hniList,
+ iwmscInfo := iwmscInfo,
+ mnpfInfo := mnpfInfo,
+ smsfInfo := smsfInfo,
+ dcsfInfoList := dcsfInfoList,
+ mrfInfoList := mrfInfoList,
+ mrfpInfoList := mrfpInfoList,
+ mfInfoList := mfInfoList,
+ adrfInfoList := adrfInfoList,
+ selectionConditions := selectionConditions,
+ canaryRelease := canaryRelease,
+ exclusiveCanaryReleaseSelection := exclusiveCanaryReleaseSelection,
+ sharedProfileDataId := sharedProfileDataId,
+ shutdownTime := shutdownTime,
+ supportedRcfs := supportedRcfs,
+ canaryPrecedenceOverPreferred := canaryPrecedenceOverPreferred,
+ imsasInfo := imsasInfo,
+ aiotfInfoList := aiotfInfoList,
+ nssfInfo := nssfInfo,
+ admInfo := admInfo
+}
+
}
diff --git a/nrf/ConnHdlr.ttcn b/nrf/ConnHdlr.ttcn
new file mode 100644
index 0000000..14ccd1c
--- /dev/null
+++ b/nrf/ConnHdlr.ttcn
@@ -0,0 +1,305 @@
+/* NRF test suite in TTCN-3 (3GPP TS 29.510), ConnHdlr
+ * (C) 2026 by sysmocom - s.f.m.c. GmbH <info@sysmocom.de>
+ * All rights reserved.
+ * Author: Pau Espin Pedrol <pespin@sysmocom.de>
+ *
+ * Released under the terms of GNU General Public License, Version 2 or
+ * (at your option) any later version.
+ *
+ * SPDX-License-Identifier: GPL-2.0-or-later
+ */
+
+module ConnHdlr {
+
+import from TCCEncoding_Functions all;
+
+import from General_Types all;
+import from Native_Functions all;
+import from IPL4asp_Types all;
+import from Misc_Helpers all;
+
+import from Osmocom_Types all;
+import from GSM_Types all;
+
+import from HTTP2_Types all;
+import from HTTP2_Templates all;
+import from HTTP2_Functions all;
+import from HTTP2_Msg all;
+import from HTTP2_Adapter all;
+import from HTTP2_Server_Emulation all;
+
+import from Prometheus_Checker all;
+
+import from TS29510_Nnrf_NFManagement all;
+import from TS29510_Nnrf_NFManagement_Templates all;
+
+import from NRF_Tests all;
+
+const integer HTTP2_CONN_SCP := 0;
+
+type record ConnHdlrPars {
+ integer idx,
+ charstring nf_instance_id,
+ NFType1_enum nf_type
+}
+
+type component ConnHdlr extends HTTP2_CT, HTTP2_ConnHdlr, Prometheus_Checker_CT {
+ var ConnHdlrPars g_pars;
+}
+
+type function void_fn() runs on ConnHdlr;
+
+function f_ConnHdlrPars(integer idx := 0, NFType1_enum nf_type := AMF) return ConnHdlrPars
+{
+ var template (value) ConnHdlrPars pars := {
+ idx := idx,
+ nf_instance_id := int2str(idx),
+ nf_type := nf_type
+ };
+ return valueof(pars);
+}
+
+function f_ConnHdlr_init(void_fn fn, ConnHdlrPars pars) runs on ConnHdlr {
+ /* make parameters available via component variable */
+ g_pars := pars;
+
+ /* Setup */
+ f_http2_adapter_init();
+
+ fn.apply();
+}
+
+function f_http2_adapter_connect_nrf(integer idx := 0)
+runs on ConnHdlr {
+ f_http2_adapter_connect(mp_nrf_hostname, mp_nrf_sbi_port, mp_nf_local_ip, idx := idx);
+}
+
+function f_http2_adapter_connect_send_nrf(template (value) HTTP2_Msg http2_msg, integer idx := 0)
+runs on ConnHdlr {
+ f_http2_adapter_connect_nrf(idx := idx);
+ f_http2_adapter_send(http2_msg);
+}
+
+function f_ts_PlmnIdNid1()
+runs on ConnHdlr return TS29510_Nnrf_NFManagement.PlmnIdNid1 {
+ return valueof(TS29510_Nnrf_NFManagement_Templates.ts_PlmnIdNid1("001", "001"));
+}
+
+
+function f_ts_Guami1()
+runs on ConnHdlr return TS29510_Nnrf_NFManagement.Guami1 {
+ var template (value) TS29510_Nnrf_NFManagement.PlmnIdNid1 plmn_id_nid := f_ts_PlmnIdNid1();
+ return valueof(TS29510_Nnrf_NFManagement_Templates.ts_Guami1(plmnId := plmn_id_nid,
+ amfId := "020040"));
+}
+
+/********************************************
+ * SCP
+/*******************************************/
+const charstring c_SCP_uri_hostport := mp_scp_local_ip & ":" & int2str(mp_scp_local_port);
+const charstring c_SCP_uri_prefix := "http://" & c_SCP_uri_hostport;
+
+/***********************************************************************
+ * Nnrf_NFManagement (SBI): Emulated NF, 3GPP TS 29.510
+ ***********************************************************************/
+const charstring c_Nnrf_NFM_uri_hostport := mp_nrf_hostname & ":" & int2str(mp_nrf_sbi_port);
+const charstring c_Nnrf_NFM_uri_prefix := "http://" & c_Nnrf_NFM_uri_hostport;
+
+/* 3GPP TS 29.510 6.1.3.3.3.2 Resource: nf-instance (Document) (PUT) */
+private function f_Nnrf_NFM_prepare_put_NFRegister(NFProfile1 nfprofile)
+runs on ConnHdlr return HTTP2_Msg {
+ var octetstring nfprofile_enc;
+ var integer http2_idx;
+ var integer http2_stream_id;
+ var template (value) HTTP2_Msg http2_tx;
+
+ nfprofile_enc := f_enc_NFProfile1(nfprofile);
+
+ http2_idx := f_http2_adapter_find_free_idx();
+ http2_stream_id := f_http2_adapter_next_stream_id(http2_idx);
+ http2_tx := ts_HTTP2_Msg(http2_idx,
+ http2_stream_id,
+ hb := {
+ pseudo_headers := ts_HTTP2_pseudo_headers_Req(method := "PUT",
+ scheme := "http",
+ authority := c_Nnrf_NFM_uri_hostport,
+ path := ts_Nnrf_NFM_path_nf_instance(g_pars.nf_instance_id)),
+ headers := {
+ ts_HTTP2_Hdr_content_type("application/json"),
+ ts_HTTP2_Hdr_accept("application/json"),
+ ts_HTTP2_Hdr_user_agent("ttcn3-nf"),
+ ts_HTTP2_Hdr_accept_encoding("gzip"),
+ ts_HTTP2_header_field("3gpp-sbi-discovery-service-names", "nnrf-nfm"),
+ ts_HTTP2_header_field("3gpp-sbi-max-rsp-time", int2str(10000)),
+ ts_HTTP2_header_field("3gpp-sbi-discovery-target-nf-type", "NRF")
+ }
+ },
+ body := ts_HTTP2_Data_frame(http2_stream_id,
+ end_stream_flag := true,
+ data := nfprofile_enc));
+ return valueof(http2_tx);
+}
+
+/* 3GPP TS 23.502 4.17.1 NF service Registration
+ * 3GPP TS 29.510 5.2.2.2.2 NF (other than NRF) registration to NRF
+ * 3GPP TS 29.510 6.1.3.3.3.2 Resource: nf-instance (Document) (PUT) */
+function f_Nnrf_NFM_put_NFRegister(integer exp_resp_code := 201)
+runs on ConnHdlr {
+ var HTTP2_Msg http2_tx;
+ var HTTP2_Msg http2_rx;
+ var template (present) HTTP2_Msg http2_exp_rx;
+ var template (value) NFProfile1 nfprofile;
+
+ nfprofile := ts_NFProfile1(nfInstanceId := g_pars.nf_instance_id,
+ nfType := ts_NFType1(g_pars.nf_type),
+ nfStatus := ts_NFStatus1(REGISTERED),
+ ipv4Addresses := { mp_nf_local_ip },
+ priority := 0,
+ capacity := 180,
+ load := 0,
+ amfInfo := ts_AmfInfo1(amfSetId := g_pars.nf_instance_id,
+ amfRegionId := int2str(g_pars.idx),
+ guamiList := { f_ts_Guami1() }),
+ nfProfileChangesSupportInd := true);
+
+ http2_tx := f_Nnrf_NFM_prepare_put_NFRegister(valueof(nfprofile));
+ f_http2_adapter_connect_send_nrf(http2_tx, idx := http2_tx.conn_id);
+
+ /* 3GPP TS 29.510 Table 6.1.3.3.3.2-3 */
+ http2_exp_rx :=
+ tr_HTTP2_Msg(http2_tx.conn_id,
+ http2_tx.stream_id,
+ tr_HTTP2_header_block(pseudo_headers := tr_HTTP2_pseudo_headers_Resp(exp_resp_code)),
+ tr_HTTP2_Data_frame(stream_id := http2_tx.stream_id,
+ end_stream_flag := true,
+ data := decmatch tr_NFProfile1));
+ as_http2_adapter_receive(http2_rx, http2_exp_rx, idx := http2_tx.conn_id);
+
+ if (exp_resp_code == 201) {
+ /* Make sure location is present in the response: */
+ var charstring created_location := valueof(f_HTTP2_header_list_find_header(http2_rx.hb.headers, c_HTTP2_HDR_location));
+ if (not match(created_location, ts_Nnrf_NFM_path_nf_instance(g_pars.nf_instance_id))) {
+ Misc_Helpers.f_shutdown(__BFILE__, __LINE__, fail,
+ log2str("Unexpected location Header ", created_location,
+ " vs exp ", ts_Nnrf_NFM_path_nf_instance(g_pars.nf_instance_id)));
+ }
+ }
+
+ f_http2_adapter_close(idx := http2_tx.conn_id);
+ setverdict(pass);
+}
+
+/* 3GPP TS 29.510 6.1.3.3.3.3 Resource: nf-instance (Document) (PATCH) */
+private function f_Nnrf_NFM_prepare_patch_NFUpdate(template (value) PatchItem1_list patch_item_li)
+runs on ConnHdlr return HTTP2_Msg {
+ var octetstring patch_item_li_enc;
+ var integer http2_idx;
+ var integer http2_stream_id;
+ var template (value) HTTP2_Msg http2_tx;
+
+ patch_item_li_enc := f_enc_PatchItem1_list(valueof(patch_item_li));
+
+ http2_idx := f_http2_adapter_find_free_idx();
+ http2_stream_id := f_http2_adapter_next_stream_id(http2_idx);
+ http2_tx := ts_HTTP2_Msg(http2_idx,
+ http2_stream_id,
+ hb := {
+ pseudo_headers := ts_HTTP2_pseudo_headers_Req(method := "PATCH",
+ scheme := "http",
+ authority := c_Nnrf_NFM_uri_hostport,
+ path := ts_Nnrf_NFM_path_nf_instance(g_pars.nf_instance_id)),
+ headers := {
+ ts_HTTP2_Hdr_content_type("application/json-patch+json"),
+ ts_HTTP2_Hdr_accept("application/json"),
+ ts_HTTP2_Hdr_user_agent("ttcn3-nf"),
+ ts_HTTP2_Hdr_accept_encoding("gzip"),
+ ts_HTTP2_header_field("3gpp-sbi-discovery-service-names", "nnrf-nfm"),
+ ts_HTTP2_header_field("3gpp-sbi-max-rsp-time", int2str(10000)),
+ ts_HTTP2_header_field("3gpp-sbi-discovery-target-nf-type", "NRF")
+ }
+ },
+ body := ts_HTTP2_Data_frame(http2_stream_id,
+ end_stream_flag := true,
+ data := patch_item_li_enc));
+ return valueof(http2_tx);
+}
+
+/* 3GPP TS 23.502 4.17.2 NF service update
+ * 3GPP TS 29.510 5.2.2.3 NFUpdate
+ * 3GPP TS 29.510 6.1.3.3.3.3 Resource: nf-instance (Document) (PATCH) */
+function f_Nnrf_NFM_patch_NFUpdate(template (value) PatchItem1_list patch_item_li)
+runs on ConnHdlr {
+ var HTTP2_Msg http2_tx;
+ var HTTP2_Msg http2_rx;
+ var template (present) HTTP2_Msg http2_exp_rx;
+
+ http2_tx := f_Nnrf_NFM_prepare_patch_NFUpdate(patch_item_li);
+ f_http2_adapter_connect_send_nrf(http2_tx, idx := http2_tx.conn_id);
+
+ /* 3GPP TS 29.510 Table Table 6.1.3.3.3.3-3 */
+ http2_exp_rx :=
+ tr_HTTP2_Msg(http2_tx.conn_id,
+ http2_tx.stream_id,
+ tr_HTTP2_header_block(pseudo_headers := tr_HTTP2_pseudo_headers_Resp(204)),
+ omit);
+ as_http2_adapter_receive(http2_rx, http2_exp_rx, idx := http2_tx.conn_id);
+
+ f_http2_adapter_close(idx := http2_tx.conn_id);
+ setverdict(pass);
+}
+
+/* 3GPP TS 29.510 6.1.3.3.3.4 Resource: nf-instance (Document) (DELETE) */
+private function f_Nnrf_NFM_prepare_delete_NFDeregister()
+runs on ConnHdlr return HTTP2_Msg {
+ var integer http2_idx;
+ var integer http2_stream_id;
+ var template (value) HTTP2_Msg http2_tx;
+
+ http2_idx := f_http2_adapter_find_free_idx();
+ http2_stream_id := f_http2_adapter_next_stream_id(http2_idx);
+ http2_tx := ts_HTTP2_Msg(http2_idx,
+ http2_stream_id,
+ hb := {
+ pseudo_headers := ts_HTTP2_pseudo_headers_Req(method := "DELETE",
+ scheme := "http",
+ authority := c_Nnrf_NFM_uri_hostport,
+ path := ts_Nnrf_NFM_path_nf_instance(g_pars.nf_instance_id)),
+ headers := {
+ ts_HTTP2_Hdr_content_type("application/json"),
+ ts_HTTP2_Hdr_accept("application/json"),
+ ts_HTTP2_Hdr_user_agent("ttcn3-nf"),
+ ts_HTTP2_Hdr_accept_encoding("gzip"),
+ ts_HTTP2_header_field("3gpp-sbi-discovery-service-names", "nnrf-nfm"),
+ ts_HTTP2_header_field("3gpp-sbi-max-rsp-time", int2str(10000)),
+ ts_HTTP2_header_field("3gpp-sbi-discovery-target-nf-type", "NRF")
+ }
+ },
+ body := omit);
+ return valueof(http2_tx);
+}
+
+/* 3GPP TS 23.502 4.17.3 NF service deregistration
+ * 3GPP TS 29.510 5.2.2.4.2 NF Instance Deregistration
+ * 3GPP TS 29.510 6.1.3.3.3.4 Resource: nf-instance (Document) (DELETE) */
+function f_Nnrf_NFM_delete_NFDeregister()
+runs on ConnHdlr {
+ var HTTP2_Msg http2_tx;
+ var HTTP2_Msg http2_rx;
+ var template (present) HTTP2_Msg http2_exp_rx;
+
+ http2_tx := f_Nnrf_NFM_prepare_delete_NFDeregister();
+ f_http2_adapter_connect_send_nrf(http2_tx, idx := http2_tx.conn_id);
+
+ /* 3GPP TS 29.510 Table 6.1.3.3.3.2-3 */
+ http2_exp_rx :=
+ tr_HTTP2_Msg(http2_tx.conn_id,
+ http2_tx.stream_id,
+ tr_HTTP2_header_block(pseudo_headers := tr_HTTP2_pseudo_headers_Resp(204)),
+ omit);
+ as_http2_adapter_receive(http2_rx, http2_exp_rx, idx := http2_tx.conn_id);
+
+ f_http2_adapter_close(idx := http2_tx.conn_id);
+ setverdict(pass);
+}
+
+}
diff --git a/nrf/NRF_Tests.cfg b/nrf/NRF_Tests.cfg
new file mode 100644
index 0000000..8c19760
--- /dev/null
+++ b/nrf/NRF_Tests.cfg
@@ -0,0 +1,23 @@
+[ORDERED_INCLUDE]
+# Common configuration, shared between test suites
+"../Common.cfg"
+# testsuite specific configuration, not expected to change
+"./NRF_Tests.default"
+
+# Local configuration below
+
+[LOGGING]
+
+[TESTPORT_PARAMETERS]
+
+[MODULE_PARAMETERS]
+NRF_Tests.mp_nrf_hostname := "127.0.0.10";
+NRF_Tests.mp_nrf_sbi_port := 7777;
+NRF_Tests.mp_scp_local_ip := "127.0.0.200";
+NRF_Tests.mp_scp_local_port := 7777;
+NRF_Tests.mp_nf_local_ip := "127.0.0.6";
+
+[MAIN_CONTROLLER]
+
+[EXECUTE]
+NRF_Tests.control
diff --git a/nrf/NRF_Tests.default b/nrf/NRF_Tests.default
new file mode 100644
index 0000000..b03f59e
--- /dev/null
+++ b/nrf/NRF_Tests.default
@@ -0,0 +1,12 @@
+[LOGGING]
+FileMask := LOG_ALL | TTCN_DEBUG | TTCN_MATCHING | DEBUG_ENCDEC;
+
+[TESTPORT_PARAMETERS]
+*.TCP.noDelay := "yes" // turn off nagle
+*.HTTP.use_notification_ASPs := "yes"
+
+[MODULE_PARAMETERS]
+
+[MAIN_CONTROLLER]
+
+[EXECUTE]
diff --git a/nrf/NRF_Tests.ttcn b/nrf/NRF_Tests.ttcn
new file mode 100644
index 0000000..8685f33
--- /dev/null
+++ b/nrf/NRF_Tests.ttcn
@@ -0,0 +1,181 @@
+/* NRF test suite in TTCN-3 (3GPP TS 29.510)
+ * (C) 2026 by sysmocom - s.f.m.c. GmbH <info@sysmocom.de>
+ * All rights reserved.
+ * Author: Pau Espin Pedrol <pespin@sysmocom.de>
+ *
+ * Released under the terms of GNU General Public License, Version 2 or
+ * (at your option) any later version.
+ *
+ * SPDX-License-Identifier: GPL-2.0-or-later
+ */
+
+module NRF_Tests {
+
+import from General_Types all;
+import from Native_Functions all;
+import from IPL4asp_Types all;
+import from Misc_Helpers all;
+
+import from Osmocom_Types all;
+import from GSM_Types all;
+
+import from TCCEncoding_Functions all;
+
+import from HTTP2_Adapter all;
+import from HTTP2_Server_Emulation all;
+
+import from JSON_Generic_Templates all;
+import from TS29510_Nnrf_NFManagement_Templates all;
+
+import from ConnHdlr all;
+
+modulepar {
+ charstring mp_nrf_hostname := "127.0.0.10";
+ integer mp_nrf_sbi_port := 7777;
+
+ charstring mp_scp_local_ip := "127.0.0.200";
+ integer mp_scp_local_port := 7777;
+
+ /* IP address used as originator of our emulated AMF/SMF requests towards the UIT. */
+ charstring mp_nf_local_ip := "127.0.0.6";
+}
+
+type component MTC_CT extends HTTP2_CT, HTTP2_ConnHdlr {
+ /* emulated SCP */
+ var HTTP2_Server_Emulation_CT vc_HTTP2_SRV_SCP;
+
+ timer g_Tguard := 30.0;
+}
+
+private function f_init_http2_srv(charstring id) runs on MTC_CT {
+ id := id & "-HTTP2SRV";
+
+ var Http2ServerEmulationCfg http2_srv_cfg := {
+ http2_bind_ip := mp_scp_local_ip,
+ http2_bind_port := mp_scp_local_port,
+ one_req_per_conn := false
+ };
+
+ vc_HTTP2_SRV_SCP := HTTP2_Server_Emulation_CT.create(id) alive;
+ vc_HTTP2_SRV_SCP.start(HTTP2_Server_Emulation.main(http2_srv_cfg));
+
+ connect(self:HTTP2_CONN_PROC[HTTP2_CONN_SCP], vc_HTTP2_SRV_SCP:CONN_PROC);
+}
+
+
+private function f_init(float t_guard := 30.0) runs on MTC_CT {
+ var charstring id := testcasename();
+
+ g_Tguard.start(t_guard);
+ activate(as_Tguard());
+
+ f_init_http2_srv(id);
+}
+
+private function f_shutdown() runs on MTC_CT {
+ f_http2_server_close_conn_all();
+ setverdict(pass);
+}
+
+private function f_start_handler_create()
+runs on MTC_CT return ConnHdlr
+{
+ var ConnHdlr vc_conn;
+ var charstring id := testcasename();
+
+ vc_conn := ConnHdlr.create(id);
+
+ if (isbound(vc_HTTP2_SRV_SCP)) {
+ connect(vc_conn:HTTP2_CONN[HTTP2_CONN_SCP], vc_HTTP2_SRV_SCP:CONN);
+ connect(vc_conn:HTTP2_CONN_PROC[HTTP2_CONN_SCP], vc_HTTP2_SRV_SCP:CONN_PROC);
+ }
+
+ return vc_conn;
+}
+
+private function f_start_handler_run(ConnHdlr vc_conn, void_fn fn, ConnHdlrPars pars) runs on MTC_CT
+{
+ vc_conn.start(f_ConnHdlr_init(fn, pars));
+}
+
+/* start a connection handler with given parameters */
+private function f_start_handler(void_fn fn, ConnHdlrPars pars)
+runs on MTC_CT return ConnHdlr {
+ var ConnHdlr vc_conn;
+ vc_conn := f_start_handler_create();
+ f_start_handler_run(vc_conn, fn, pars);
+ return vc_conn;
+}
+
+private altstep as_Tguard() runs on MTC_CT {
+ [] g_Tguard.timeout {
+ Misc_Helpers.f_shutdown(__BFILE__, __LINE__, fail, "Tguard timeout");
+ }
+}
+
+/* 3GPP TS 23.502 4.17.1 NF service Registration
+ * 3GPP TS 29.510 5.2.2.2.2 NF (other than NRF) registration to NRF
+ * 3GPP TS 23.502 4.17.3 NF service deregistration
+ * 3GPP TS 29.510 5.2.2.4.2 NF Instance Deregistration */
+private function f_TC_nf_service_registration_deregistration() runs on ConnHdlr {
+ f_Nnrf_NFM_put_NFRegister();
+ f_Nnrf_NFM_delete_NFDeregister();
+ setverdict(pass);
+}
+testcase TC_nf_service_registration_deregistration() runs on MTC_CT {
+ var ConnHdlr vc_conn;
+ var ConnHdlrPars pars := f_ConnHdlrPars(0);
+ f_init();
+ vc_conn := f_start_handler(refers(f_TC_nf_service_registration_deregistration), pars);
+ vc_conn.done;
+ f_shutdown();
+}
+
+/* 3GPP TS 23.502 4.17.2 NF service update
+ * 3GPP TS 29.510 5.2.2.3 NFUpdate */
+private function f_TC_nf_service_registration_update() runs on ConnHdlr {
+ f_Nnrf_NFM_put_NFRegister();
+ f_Nnrf_NFM_patch_NFUpdate({ ts_PatchItem1(op := ts_PatchOperation1(replace_),
+ path := "/load",
+ value_ := ts_JSON_generic_val_string("20")) });
+ f_Nnrf_NFM_delete_NFDeregister();
+ setverdict(pass);
+}
+testcase TC_nf_service_registration_update() runs on MTC_CT {
+ var ConnHdlr vc_conn;
+ var ConnHdlrPars pars := f_ConnHdlrPars(0);
+ f_init();
+ vc_conn := f_start_handler(refers(f_TC_nf_service_registration_update), pars);
+ vc_conn.done;
+ f_shutdown();
+}
+
+/* Test already registed NF re-registering again.
+ * 2nd answer should be answered with 200 OK instead of 201 Created.
+ * 3GPP TS 23.502 4.17.1 NF service Registration
+ * 3GPP TS 29.510 5.2.2.2.2 NF (other than NRF) registration to NRF */
+private function f_TC_nf_service_re_registration() runs on ConnHdlr {
+ f_Nnrf_NFM_put_NFRegister(exp_resp_code := 201);
+ f_Nnrf_NFM_put_NFRegister(exp_resp_code := 200);
+ f_Nnrf_NFM_delete_NFDeregister();
+ setverdict(pass);
+}
+testcase TC_nf_service_re_registration() runs on MTC_CT {
+ var ConnHdlr vc_conn;
+ var ConnHdlrPars pars := f_ConnHdlrPars(0);
+ f_init();
+ vc_conn := f_start_handler(refers(f_TC_nf_service_re_registration), pars);
+ vc_conn.done;
+ f_shutdown();
+}
+
+
+/* TODO see procedures in 3GPP TS 23.502 4.17 */
+
+control {
+ execute( TC_nf_service_registration_deregistration() );
+ execute( TC_nf_service_registration_update() );
+ execute( TC_nf_service_re_registration() );
+}
+
+}
diff --git a/nrf/README.md b/nrf/README.md
new file mode 100644
index 0000000..8b31de2
--- /dev/null
+++ b/nrf/README.md
@@ -0,0 +1,14 @@
+# NRF_Tests.ttcn
+
+* external interfaces
+ * N27: SBI (emulates NFs or other NRF)
+
+{% dot nrf_tests.svg
+digraph G {
+ rankdir=LR;
+ ATS [label="ATS\nNRF_Tests.ttcn"];
+ NRF [label="AMF\open5gs-nrfd",shape="box"];
+
+ ATS -> NRF [label="N27"];
+}
+%}
diff --git a/nrf/expected-results.xml b/nrf/expected-results.xml
new file mode 100644
index 0000000..df2d090
--- /dev/null
+++ b/nrf/expected-results.xml
@@ -0,0 +1,6 @@
+<?xml version="1.0"?>
+<testsuite name='Titan' tests='1' failures='0' errors='0' skipped='0' inconc='0' time='MASKED'>
+ <testcase classname='NRF_Tests' name='TC_nf_service_registration_deregistration' time='MASKED'/>
+ <testcase classname='NRF_Tests' name='TC_nf_service_registration_update' time='MASKED'/>
+ <testcase classname='NRF_Tests' name='TC_nf_service_re_registration' time='MASKED'/>
+</testsuite>
diff --git a/nrf/gen_links.sh b/nrf/gen_links.sh
new file mode 100755
index 0000000..492dcf2
--- /dev/null
+++ b/nrf/gen_links.sh
@@ -0,0 +1,52 @@
+#!/bin/bash -e
+
+BASEDIR=../deps
+
+. ../_buildsystem/gen_links.inc.sh
+
+DIR=$BASEDIR/titan.Libraries.TCCUsefulFunctions/src
+FILES="TCCInterface_Functions.ttcn TCCConversion_Functions.ttcn TCCConversion.cc TCCInterface.cc TCCInterface_ip.h"
+FILES+=" TCCEncoding_Functions.ttcn TCCEncoding.cc " # GSM 7-bit coding
+gen_links $DIR $FILES
+
+DIR=$BASEDIR/titan.TestPorts.Common_Components.Socket-API/src
+FILES="Socket_API_Definitions.ttcn"
+gen_links $DIR $FILES
+
+# Required by MGCP and IPA
+DIR=$BASEDIR/titan.TestPorts.IPL4asp/src
+FILES="IPL4asp_Functions.ttcn IPL4asp_PT.cc IPL4asp_PT.hh IPL4asp_PortType.ttcn IPL4asp_Types.ttcn IPL4asp_discovery.cc IPL4asp_protocol_L234.hh"
+gen_links $DIR $FILES
+
+# Needed by HTTP_Adapter (Prometheus_Checker.ttcn metrics):
+DIR=$BASEDIR/titan.TestPorts.Common_Components.Abstract_Socket/src
+FILES="Abstract_Socket.cc Abstract_Socket.hh "
+gen_links $DIR $FILES
+
+# Needed by HTTP_Adapter (Prometheus_Checker.ttcn metrics):
+DIR=$BASEDIR/titan.TestPorts.HTTPmsg/src
+FILES="HTTPmsg_MessageLen.ttcn HTTPmsg_MessageLen_Function.cc HTTPmsg_PT.cc HTTPmsg_PT.hh HTTPmsg_PortType.ttcn HTTPmsg_Types.ttcn "
+gen_links $DIR $FILES
+
+# Needed by HTTP2_Adapter:
+DIR=$BASEDIR/titan.ProtocolModules.HTTP2/src
+FILES="HTTP2_EncDec.cc HTTP2_Types.ttcn"
+gen_links $DIR $FILES
+
+DIR=$BASEDIR/titan.ProtocolModules.JSON_v07_2006/src
+FILES="JSON_Generic_Null_Def.asn JSON_Generic.ttcn"
+gen_links $DIR $FILES
+
+DIR=$BASEDIR/osmo-ttcn3-openapi-generator/openapi-specs/3GPP_5GC_Rel19/ttcn3
+FILES="TS29571_CommonData.ttcn TS29510_Nnrf_NFManagement.ttcn "
+gen_links $DIR $FILES
+
+DIR=../library
+FILES="Misc_Helpers.ttcn General_Types.ttcn GSM_Types.ttcn Osmocom_Types.ttcn Native_Functions.ttcn Native_FunctionDefs.cc IPCP_Types.ttcn IPCP_Templates.ttcn "
+FILES+="SCTP_Templates.ttcn "
+FILES+="HTTP2_CodecPort.ttcn HTTP2_CodecPort_CtrlFunct.ttcn HTTP2_CodecPort_CtrlFunctDef.cc HTTP2_Templates.ttcn HTTP2_Functions.ttcn HTTP2_Msg.ttcn HTTP2_Adapter.ttcn HTTP2_Server_Emulation.ttcn "
+FILES+="HTTP_Adapter.ttcn Prometheus_Checker.ttcn "
+FILES+="JSON_Generic_Templates.ttcn TS29571_CommonData_Templates.ttcn TS29510_Nnrf_NFManagement_Templates.ttcn "
+gen_links $DIR $FILES
+
+gen_links_finish
diff --git a/nrf/open5gs-nrf.yaml b/nrf/open5gs-nrf.yaml
new file mode 100644
index 0000000..3d26679
--- /dev/null
+++ b/nrf/open5gs-nrf.yaml
@@ -0,0 +1,18 @@
+# See https://github.com/open5gs/open5gs/blob/main/configs/open5gs/nrf.yaml.in
+
+logger:
+ level: debug
+
+global:
+ max:
+ ue: 1024
+
+nrf:
+ serving: # 5G roaming requires PLMN in NRF
+ - plmn_id:
+ mcc: 999
+ mnc: 70
+ sbi:
+ server:
+ - address: 127.0.0.10
+ port: 7777
diff --git a/nrf/regen_makefile.sh b/nrf/regen_makefile.sh
new file mode 100755
index 0000000..2696537
--- /dev/null
+++ b/nrf/regen_makefile.sh
@@ -0,0 +1,23 @@
+#!/bin/sh -e
+
+NAME=NRF_Tests
+
+FILES="
+ *.asn
+ *.ttcn
+ Abstract_Socket.cc
+ HTTPmsg_MessageLen_Function.cc
+ HTTPmsg_PT.cc
+ HTTP2_EncDec.cc
+ HTTP2_CodecPort_CtrlFunctDef.cc
+ IPL4asp_PT.cc
+ IPL4asp_discovery.cc
+ Native_FunctionDefs.cc
+ TCCConversion.cc
+ TCCEncoding.cc
+ TCCInterface.cc
+"
+
+. ../_buildsystem/regen_makefile.inc.sh
+
+sed -i -e 's/^LINUX_LIBS = -lxml2 -lsctp/LINUX_LIBS = -lxml2 -lsctp -lgnutls/' Makefile
diff --git a/nrf/testenv.cfg b/nrf/testenv.cfg
new file mode 100644
index 0000000..a41770c
--- /dev/null
+++ b/nrf/testenv.cfg
@@ -0,0 +1,11 @@
+[testsuite]
+program=NRF_Tests
+config=NRF_Tests.cfg
+
+[nrf]
+program=open5gs-nrfd -c open5gs-nrf.yaml
+make=open5gs
+package=open5gs-nrf
+copy=open5gs-nrf.yaml
+
+
diff --git a/nrf/testsrcdir.cfg b/nrf/testsrcdir.cfg
new file mode 100644
index 0000000..7f19289
--- /dev/null
+++ b/nrf/testsrcdir.cfg
@@ -0,0 +1,2 @@
+[testsrcdir]
+max_jobs_per_gb_ram=0.3
To view, visit change 44152. To unsubscribe, or for help writing mail filters, visit settings.