pespin submitted this change.
Introduce pcf testsuite
Introduce a new "pcf" testsuite which runs against open5gs-pcfd.
Start with a single test which already contains most of the
infrastructure needed and makes it easy to extend later on.
Related: SYS#7073
Change-Id: I8e8a3b940f588036351e6ddf1c0a93a7d1a60b7d
---
M Makefile
M library/TS29512_Npcf_SMPolicyControl_Templates.ttcn
A library/TS29519_Policy_Data_Templates.ttcn
A library/TS29521_Nbsf_Management_Templates.ttcn
A pcf/ConnHdlr.ttcn
A pcf/PCF_Tests.cfg
A pcf/PCF_Tests.default
A pcf/PCF_Tests.ttcn
A pcf/README.md
A pcf/create_test_subscribers.sh
A pcf/expected-results.xml
A pcf/gen_links.sh
A pcf/mongod.conf
A pcf/open5gs-pcf.yaml
A pcf/regen_makefile.sh
A pcf/testenv.cfg
A pcf/testsrcdir.cfg
M smf/SMF_Session_CT_5G.ttcn
18 files changed, 1,118 insertions(+), 6 deletions(-)
diff --git a/Makefile b/Makefile
index 459929a..d583aad 100644
--- a/Makefile
+++ b/Makefile
@@ -42,6 +42,7 @@
ns \
pcap-client \
pcu \
+ pcf \
pcrf \
pgw \
remsim \
diff --git a/library/TS29512_Npcf_SMPolicyControl_Templates.ttcn b/library/TS29512_Npcf_SMPolicyControl_Templates.ttcn
index 8c16e72..b48e619 100644
--- a/library/TS29512_Npcf_SMPolicyControl_Templates.ttcn
+++ b/library/TS29512_Npcf_SMPolicyControl_Templates.ttcn
@@ -8,15 +8,38 @@
const charstring c_Npcf_SMPolicyControl_path_sm_policies := c_Npcf_SMPolicyControl_path_api_prefix & "/sm-policies";
/* 5.3.3 Resource: Individual SM Policy */
-template (present) charstring
-tr_Npcf_SMPolicyControl_path_individual_sm_policy_delete(template (present) charstring sm_policy_id := pattern "?+")
-:= pattern c_Npcf_SMPolicyControl_path_sm_policies & "/" & sm_policy_id & "/delete";
-
template (value) charstring
ts_Npcf_SMPolicyControl_path_individual_sm_policy(template (value) charstring sm_policy_id)
:= c_Npcf_SMPolicyControl_path_sm_policies & "/" & valueof(sm_policy_id);
+template (present) charstring
+tr_Npcf_SMPolicyControl_path_individual_sm_policy_delete(template (present) charstring sm_policy_id := pattern "?+")
+:= pattern c_Npcf_SMPolicyControl_path_sm_policies & "/" & sm_policy_id & "/delete";
+
+
+template (value) PduSessionType1
+ts_PduSessionType1(PduSessionType1_enum enum_val) := {
+ enum_val := enum_val
+}
+
+
+template (value) PlmnIdNid1
+ts_PlmnIdNid1(template (value) Mcc mcc,
+ template (value) Mnc mnc,
+ template (omit) Nid nid := omit) := {
+ mcc := mcc,
+ mnc := mnc,
+ nid := nid
+}
+
+template (value) Snssai1
+ts_Snssai1(template (value) integer sst,
+ template (omit) charstring sd := omit) := {
+ sst := sst,
+ sd := sd
+}
+
template (present) SmPolicyContextData1
tr_SmPolicyContextData1(template AccNetChId1 accNetChId := *,
template AccNetChargingAddress1 chargEntityAddr := *,
@@ -139,6 +162,128 @@
trafficDescriptors := trafficDescriptors
}
+template (value) SmPolicyContextData1
+ts_SmPolicyContextData1(template (omit) AccNetChId1 accNetChId := omit,
+ template (omit) AccNetChargingAddress1 chargEntityAddr := omit,
+ template (omit) Gpsi1 gpsi := omit,
+ template (value) Supi1 supi,
+ template (omit) boolean invalidSupi := omit,
+ template (omit) record of GroupId1 interGrpIds := omit,
+ template (value) PduSessionId1 pduSessionId,
+ template (value) PduSessionType1 pduSessionType,
+ template (omit) charstring chargingcharacteristics := omit,
+ template (value) Dnn1 dnn,
+ template (omit) DnnSelectionMode1 dnnSelMode := omit,
+ template (value) Uri1 notificationUri,
+ template (omit) AccessType1 accessType := omit,
+ template (omit) RatType1 ratType := omit,
+ template (omit) AdditionalAccessInfo1 addAccessInfo := omit,
+ template (omit) PlmnIdNid1 servingNetwork := omit,
+ template (omit) UserLocation1 userLocationInfo := omit,
+ template (omit) TimeZone1 ueTimeZone := omit,
+ template (omit) Pei1 pei := omit,
+ template (omit) Ipv4Addr1 ipv4Address := omit,
+ template (omit) Ipv6Prefix1 ipv6AddressPrefix := omit,
+ template (omit) charstring ipDomain := omit,
+ template (omit) Ambr1 subsSessAmbr := omit,
+ template (omit) charstring authProfIndex := omit,
+ template (omit) SubscribedDefaultQos1 subsDefQos := omit,
+ template (omit) VplmnQos1 vplmnQos := omit,
+ template (omit) integer numOfPackFilter := omit,
+ template (omit) boolean online := omit,
+ template (omit) boolean offline := omit,
+ template (omit) boolean threegppPsDataOffStatus := omit,
+ template (omit) boolean refQosIndication := omit,
+ template (omit) TraceData1 traceReq := omit,
+ template (value) Snssai1 sliceInfo,
+ template (omit) Snssai1 altSliceInfo := omit,
+ template (omit) QosFlowUsage1 qosFlowUsage := omit,
+ template (omit) ServingNfIdentity1 servNfId := omit,
+ template (omit) SupportedFeatures1 suppFeat := omit,
+ template (omit) NfInstanceId1 smfId := omit,
+ template (omit) DateTime1 recoveryTime := omit,
+ template (omit) MaPduIndication1 maPduInd := omit,
+ template (omit) AtsssCapability1 atsssCapab := omit,
+ template (omit) SmPolicyContextData1.atsssCapabs atsssCapabs := omit,
+ template (omit) SmPolicyContextData1.ipv4FrameRouteList ipv4FrameRouteList := omit,
+ template (omit) SmPolicyContextData1.ipv6FrameRouteList ipv6FrameRouteList := omit,
+ template (omit) SatelliteBackhaulCategory1 satBackhaulCategory := omit,
+ template (omit) PcfUeCallbackInfo1 pcfUeInfo := omit,
+ template (omit) SmPolicyContextData1.pvsInfo pvsInfo := omit,
+ template (omit) boolean onboardInd := omit,
+ template (omit) SmPolicyContextData1.nwdafDatas nwdafDatas := omit,
+ template (omit) UrspEnforcementInfo1 urspEnfInfo := omit,
+ template (omit) SscMode1 sscMode := omit,
+ template (omit) Dnn1 ueReqDnn := omit,
+ template (omit) PduSessionType1 ueReqPduSessionType := omit,
+ template (omit) boolean hrsboInd := omit,
+ template (omit) boolean locOffloadInd := omit,
+ template (omit) UePolicyTransferFailureCause1 uePolFailReport := omit,
+ template (omit) boolean urspProvSuppInd := omit,
+ template (omit) boolean mpxMediaInd := omit,
+ template (omit) SmPolicyContextData1.trafficDescriptors trafficDescriptors := omit
+) := {
+ accNetChId := accNetChId,
+ chargEntityAddr := chargEntityAddr,
+ gpsi := gpsi,
+ supi := supi,
+ invalidSupi := invalidSupi,
+ interGrpIds := interGrpIds,
+ pduSessionId := pduSessionId,
+ pduSessionType := pduSessionType,
+ chargingcharacteristics := chargingcharacteristics,
+ dnn := dnn,
+ dnnSelMode := dnnSelMode,
+ notificationUri := notificationUri,
+ accessType := accessType,
+ ratType := ratType,
+ addAccessInfo := addAccessInfo,
+ servingNetwork := servingNetwork,
+ userLocationInfo := userLocationInfo,
+ ueTimeZone := ueTimeZone,
+ pei := pei,
+ ipv4Address := ipv4Address,
+ ipv6AddressPrefix := ipv6AddressPrefix,
+ ipDomain := ipDomain,
+ subsSessAmbr := subsSessAmbr,
+ authProfIndex := authProfIndex,
+ subsDefQos := subsDefQos,
+ vplmnQos := vplmnQos,
+ numOfPackFilter := numOfPackFilter,
+ online := online,
+ offline := offline,
+ threegppPsDataOffStatus := threegppPsDataOffStatus,
+ refQosIndication := refQosIndication,
+ traceReq := traceReq,
+ sliceInfo := sliceInfo,
+ altSliceInfo := altSliceInfo,
+ qosFlowUsage := qosFlowUsage,
+ servNfId := servNfId,
+ suppFeat := suppFeat,
+ smfId := smfId,
+ recoveryTime := recoveryTime,
+ maPduInd := maPduInd,
+ atsssCapab := atsssCapab,
+ atsssCapabs := atsssCapabs,
+ ipv4FrameRouteList := ipv4FrameRouteList,
+ ipv6FrameRouteList := ipv6FrameRouteList,
+ satBackhaulCategory := satBackhaulCategory,
+ pcfUeInfo := pcfUeInfo,
+ pvsInfo := pvsInfo,
+ onboardInd := onboardInd,
+ nwdafDatas := nwdafDatas,
+ urspEnfInfo := urspEnfInfo,
+ sscMode := sscMode,
+ ueReqDnn := ueReqDnn,
+ ueReqPduSessionType := ueReqPduSessionType,
+ hrsboInd := hrsboInd,
+ locOffloadInd := locOffloadInd,
+ uePolFailReport := uePolFailReport,
+ urspProvSuppInd := urspProvSuppInd,
+ mpxMediaInd := mpxMediaInd,
+ trafficDescriptors := trafficDescriptors
+}
+
type TS29512_Npcf_SMPolicyControl.SmPolicyDecision1.sessRules SessRulesMap;
type TS29512_Npcf_SMPolicyControl.SmPolicyDecision1.pccRules PccRulesNullableMap;
type TS29512_Npcf_SMPolicyControl.SmPolicyDecision1.qosDecs QosDecsMap;
@@ -153,6 +298,88 @@
type TS29512_Npcf_SMPolicyControl.SmPolicyDecision1.vplmnOffloadInfos VplmnOffloadingInfo1Map;
type TS29512_Npcf_SMPolicyControl.SmPolicyDecision1.locOffloadInfos LocalOffloadingManagementInfo1Map;
+template (present) SmPolicyDecision1
+tr_SmPolicyDecision1(template SessRulesMap sessRules := *,
+ template PccRulesNullableMap pccRules := *,
+ template boolean pcscfRestIndication := *,
+ template QosDecsMap qosDecs := *,
+ template ChgDecsNullableMap chgDecs := *,
+ template ChargingInformation1 chargingInfo := *,
+ template NfGroupId1 chfGroupId := *,
+ template TraffContDecsMap traffContDecs := *,
+ template UmDecsNullableMap umDecs := *,
+ template QosCharsMap qosChars := *,
+ template QosMonDecsNullableMap qosMonDecs := *,
+ template DurationSec1 reflectiveQoSTimer := *,
+ template ConditionData1NullableMap conds := *,
+ template DateTime1 revalidationTime := *,
+ template boolean offline := *,
+ template boolean online := *,
+ template boolean offlineChOnly := *,
+ template PolicyCtrlReqTriggersMap policyCtrlReqTriggers := *,
+ template SmPolicyDecision1.lastReqRuleData lastReqRuleData := *,
+ template RequestedUsageData1 lastReqUsageData := *,
+ template PresenceInfoRm1NullableMap praInfos := *,
+ template IpIndex1 ipv4Index := *,
+ template IpIndex1 ipv6Index := *,
+ template QosFlowUsage1 qosFlowUsage := *,
+ template SmPolicyDecision1.qosMonCapRepoTypes qosMonCapRepoTypes := *,
+ template SmPolicyAssociationReleaseCause1 relCause := *,
+ template SupportedFeatures1 suppFeat := *,
+ template BridgeManagementContainer1 tsnBridgeManCont := *,
+ template PortManagementContainer1 tsnPortManContDstt := *,
+ template SmPolicyDecision1.tsnPortManContNwtts tsnPortManContNwtts := *,
+ template Uri1 tscNotifUri := *,
+ template charstring tscNotifCorreId := *,
+ template boolean redSessIndication := *,
+ template UePolicyContainer1 uePolCont := *,
+ template SliceUsgCtrlInfo1 sliceUsgCtrlInfo := *,
+ template VplmnOffloadingInfo1Map vplmnOffloadInfos := *,
+ template LocalOffloadingManagementInfo1Map locOffloadInfos := *,
+ template VplmnDlAmbr1 vplmnDlAmbr := *,
+ template PcSessionRecoveryStatus1 sessionRecovStatus:= *
+) := {
+ sessRules := sessRules,
+ pccRules := pccRules,
+ pcscfRestIndication := pcscfRestIndication,
+ qosDecs := qosDecs,
+ chgDecs := chgDecs,
+ chargingInfo := chargingInfo,
+ chfGroupId := chfGroupId,
+ traffContDecs := traffContDecs,
+ umDecs := umDecs,
+ qosChars := qosChars,
+ qosMonDecs := qosMonDecs,
+ reflectiveQoSTimer := reflectiveQoSTimer,
+ conds := conds,
+ revalidationTime := revalidationTime,
+ offline := offline,
+ online := online,
+ offlineChOnly := offlineChOnly,
+ policyCtrlReqTriggers := policyCtrlReqTriggers,
+ lastReqRuleData := lastReqRuleData,
+ lastReqUsageData := lastReqUsageData,
+ praInfos := praInfos,
+ ipv4Index := ipv4Index,
+ ipv6Index := ipv6Index,
+ qosFlowUsage := qosFlowUsage,
+ qosMonCapRepoTypes := qosMonCapRepoTypes,
+ relCause := relCause,
+ suppFeat := suppFeat,
+ tsnBridgeManCont := tsnBridgeManCont,
+ tsnPortManContDstt := tsnPortManContDstt,
+ tsnPortManContNwtts := tsnPortManContNwtts,
+ tscNotifUri := tscNotifUri,
+ tscNotifCorreId := tscNotifCorreId,
+ redSessIndication := redSessIndication,
+ uePolCont := uePolCont,
+ sliceUsgCtrlInfo := sliceUsgCtrlInfo,
+ vplmnOffloadInfos := vplmnOffloadInfos,
+ locOffloadInfos := locOffloadInfos,
+ vplmnDlAmbr := vplmnDlAmbr,
+ sessionRecovStatus := sessionRecovStatus
+}
+
template (value) SmPolicyDecision1
ts_SmPolicyDecision1(template (omit) SessRulesMap sessRules := omit,
template (omit) PccRulesNullableMap pccRules := omit,
diff --git a/library/TS29519_Policy_Data_Templates.ttcn b/library/TS29519_Policy_Data_Templates.ttcn
new file mode 100644
index 0000000..d6b3d23
--- /dev/null
+++ b/library/TS29519_Policy_Data_Templates.ttcn
@@ -0,0 +1,106 @@
+module TS29519_Policy_Data_Templates {
+
+import from TS29519_Policy_Data all;
+
+const charstring c_Nudr_DR_policy_data_path_api_prefix := "/nudr-dr/v1/policy-data";
+
+template (present) charstring
+tr_Nudr_DR_policy_data_path_sm_data(template (present) charstring imsi := pattern "\d+")
+:= pattern c_Nudr_DR_policy_data_path_api_prefix & "/ues/imsi-" & imsi & "/sm-data*";
+
+
+template (value) Snssai
+ts_Snssai(template (value) integer sst,
+ template (omit) charstring sd := omit) := {
+ sst := sst,
+ sd := sd
+}
+
+type TS29519_Policy_Data.SmPolicyDnnData.spendLimInfo SpendLimInfoMap;
+type TS29519_Policy_Data.SmPolicyDnnData.refUmDataLimitIds RefUmDataLimitIdsMap;
+type TS29519_Policy_Data.SmPolicyDnnData.praInfos PraInfosMap;
+type TS29519_Policy_Data.SmPolicyDnnData.bdtRefIds BdtRefIdsUnion;
+type TS29519_Policy_Data.SmPolicyDnnData.tnaps TnapIdList;
+type TS29519_Policy_Data.SmPolicyDnnData.restriStatus RestrictedStatusList;
+template (value) SmPolicyDnnData
+ts_SmPolicyDnnData(template (value) Dnn dnn,
+ template (omit) record of charstring allowedServices := omit,
+ template (omit) record of charstring subscCats := omit,
+ template (omit) BitRate gbrUl := omit,
+ template (omit) BitRate gbrDl := omit,
+ template (omit) boolean adcSupport := omit,
+ template (omit) boolean subscSpendingLimits := omit,
+ template (omit) SpendLimInfoMap spendLimInfo := omit,
+ template (omit) IpIndex ipv4Index := omit,
+ template (omit) IpIndex ipv6Index := omit,
+ template (omit) boolean offline := omit,
+ template (omit) boolean online := omit,
+ template (omit) ChargingInformation chfInfo := omit,
+ template (omit) NfGroupId chfGroupId := omit,
+ template (omit) RefUmDataLimitIdsMap refUmDataLimitIds := omit,
+ template (omit) boolean mpsPriority := omit,
+ template (omit) boolean mcsPriority := omit,
+ template (omit) boolean imsSignallingPrio := omit,
+ template (omit) integer mpsPriorityLevel := omit,
+ template (omit) integer mcsPriorityLevel := omit,
+ template (omit) PraInfosMap praInfos := omit,
+ template (omit) BdtRefIdsUnion bdtRefIds := omit,
+ template (omit) boolean locRoutNotAllowed := omit,
+ template (omit) boolean sfcNotAllowed := omit,
+ template (omit) TnapIdList tnaps := omit,
+ template (omit) RestrictedStatusList restriStatus := omit,
+ template (omit) boolean headerNotAllowed := omit) := {
+ dnn := dnn,
+ allowedServices := allowedServices,
+ subscCats := subscCats,
+ gbrUl := gbrUl,
+ gbrDl := gbrDl,
+ adcSupport := adcSupport,
+ subscSpendingLimits := subscSpendingLimits,
+ spendLimInfo := spendLimInfo,
+ ipv4Index := ipv4Index,
+ ipv6Index := ipv6Index,
+ offline := offline,
+ online := online,
+ chfInfo := chfInfo,
+ chfGroupId := chfGroupId,
+ refUmDataLimitIds := refUmDataLimitIds,
+ mpsPriority := mpsPriority,
+ mcsPriority := mcsPriority,
+ imsSignallingPrio := imsSignallingPrio,
+ mpsPriorityLevel := mpsPriorityLevel,
+ mcsPriorityLevel := mcsPriorityLevel,
+ praInfos := praInfos,
+ bdtRefIds := bdtRefIds,
+ locRoutNotAllowed := locRoutNotAllowed,
+ sfcNotAllowed := sfcNotAllowed,
+ tnaps := tnaps,
+ restriStatus := restriStatus,
+ headerNotAllowed := headerNotAllowed
+}
+
+type TS29519_Policy_Data.SmPolicySnssaiData.smPolicyDnnData SmPolicyDnnDataMap;
+template (value) SmPolicySnssaiData
+ts_SmPolicySnssaiData(template (value) Snssai snssai,
+ template (omit) SmPolicyDnnDataMap smPolicyDnnData := omit,
+ template (omit) SliceMbr ueSliceMbr := omit) := {
+ snssai := snssai,
+ smPolicyDnnData := smPolicyDnnData,
+ ueSliceMbr := ueSliceMbr
+}
+
+type TS29519_Policy_Data.SmPolicyData.smPolicySnssaiData SmPolicySnssaiDataMap;
+type TS29519_Policy_Data.SmPolicyData.umDataLimits UmDataLimitsMap;
+type TS29519_Policy_Data.SmPolicyData.umData UmDataMap;
+template (value) SmPolicyData
+ts_SmPolicyData(template (value) SmPolicySnssaiDataMap smPolicySnssaiData,
+ template (omit) UmDataLimitsMap umDataLimits := omit,
+ template (omit) UmDataMap umData := omit,
+ template (omit) SupportedFeatures suppFeat := omit) := {
+ smPolicySnssaiData := smPolicySnssaiData,
+ umDataLimits := umDataLimits,
+ umData := umData,
+ suppFeat := suppFeat
+}
+
+}
diff --git a/library/TS29521_Nbsf_Management_Templates.ttcn b/library/TS29521_Nbsf_Management_Templates.ttcn
new file mode 100644
index 0000000..4e14679
--- /dev/null
+++ b/library/TS29521_Nbsf_Management_Templates.ttcn
@@ -0,0 +1,71 @@
+module TS29521_Nbsf_Management_Templates {
+
+import from TS29521_Nbsf_Management all;
+
+const charstring c_Nbsf_Management_path_api_prefix := "/nbsf-management/v1";
+const charstring c_Nbsf_Management_path_pcfBindings
+:= c_Nbsf_Management_path_api_prefix & "/pcfBindings";
+
+/* 5.3.3 Resource: Individual PCF for a PDU Session Binding */
+template (value) charstring
+ts_Nbsf_Management_path_individual_pcf_pdu_sess_binding(template (value) charstring binding_id)
+:= c_Nbsf_Management_path_pcfBindings & "/" & valueof(binding_id);
+
+type TS29521_Nbsf_Management.PcfBinding.addIpv6Prefixes Ipv6PrefixList;
+type TS29521_Nbsf_Management.PcfBinding.addMacAddrs MacAddr48List;
+type TS29521_Nbsf_Management.PcfBinding.pcfIpEndPoints PcfIpEndPointList;
+type TS29521_Nbsf_Management.PcfBinding.pcfSmIpEndPoints PcfSmIpEndPointList;
+type TS29521_Nbsf_Management.PcfBinding.ipv4FrameRouteList Ipv4FrameRouteList;
+type TS29521_Nbsf_Management.PcfBinding.ipv6FrameRouteList Ipv6FrameRouteList;
+template (present) PcfBinding
+tr_PcfBinding(template Supi supi := *,
+ template Gpsi gpsi := *,
+ template Ipv4Addr ipv4Addr := *,
+ template Ipv6Prefix ipv6Prefix := *,
+ template Ipv6PrefixList addIpv6Prefixes := *,
+ template charstring ipDomain := *,
+ template MacAddr48 macAddr48 := *,
+ template MacAddr48List addMacAddrs := *,
+ template (present) Dnn dnn := ?,
+ template Fqdn pcfFqdn := *,
+ template PcfIpEndPointList pcfIpEndPoints := *,
+ template DiameterIdentity pcfDiamHost := *,
+ template DiameterIdentity pcfDiamRealm := *,
+ template Fqdn pcfSmFqdn := *,
+ template PcfSmIpEndPointList pcfSmIpEndPoints := *,
+ template (present) Snssai snssai := ?,
+ template SupportedFeatures suppFeat := *,
+ template NfInstanceId pcfId := *,
+ template NfSetId pcfSetId := *,
+ template DateTime recoveryTime := *,
+ template ParameterCombination paraCom := *,
+ template BindingLevel bindLevel := *,
+ template Ipv4FrameRouteList ipv4FrameRouteList := *,
+ template Ipv6FrameRouteList ipv6FrameRouteList := *) := {
+ supi := supi,
+ gpsi := gpsi,
+ ipv4Addr := ipv4Addr,
+ ipv6Prefix := ipv6Prefix,
+ addIpv6Prefixes := addIpv6Prefixes,
+ ipDomain := ipDomain,
+ macAddr48 := macAddr48,
+ addMacAddrs := addMacAddrs,
+ dnn := dnn,
+ pcfFqdn := pcfFqdn,
+ pcfIpEndPoints := pcfIpEndPoints,
+ pcfDiamHost := pcfDiamHost,
+ pcfDiamRealm := pcfDiamRealm,
+ pcfSmFqdn := pcfSmFqdn,
+ pcfSmIpEndPoints := pcfSmIpEndPoints,
+ snssai := snssai,
+ suppFeat := suppFeat,
+ pcfId := pcfId,
+ pcfSetId := pcfSetId,
+ recoveryTime := recoveryTime,
+ paraCom := paraCom,
+ bindLevel := bindLevel,
+ ipv4FrameRouteList := ipv4FrameRouteList,
+ ipv6FrameRouteList := ipv6FrameRouteList
+}
+
+}
diff --git a/pcf/ConnHdlr.ttcn b/pcf/ConnHdlr.ttcn
new file mode 100644
index 0000000..4894e0f
--- /dev/null
+++ b/pcf/ConnHdlr.ttcn
@@ -0,0 +1,319 @@
+/* PCF test suite in TTCN-3 (3GPP TS 29.512), ConnHdlr
+ * (C) 2026 by sysmocom - s.f.m.c. GmbH <info@sysmocom.de>
+ * All rights reserved.
+ * Author: Pau Espin Pedrol <pespin@sysmocom.de>
+ *
+ * Released under the terms of GNU General Public License, Version 2 or
+ * (at your option) any later version.
+ *
+ * SPDX-License-Identifier: GPL-2.0-or-later
+ */
+
+module ConnHdlr {
+
+import from TCCEncoding_Functions all;
+
+import from General_Types all;
+import from Native_Functions all;
+import from IPL4asp_Types all;
+import from Misc_Helpers all;
+
+import from Osmocom_Types all;
+import from GSM_Types all;
+
+import from HTTP2_Types all;
+import from HTTP2_Templates all;
+import from HTTP2_Functions all;
+import from HTTP2_Msg all;
+import from HTTP2_Adapter all;
+import from HTTP2_Server_Emulation all;
+
+import from Prometheus_Checker all;
+
+import from TS29571_CommonData_Templates all;
+import from TS29505_Subscription_Data all;
+import from TS29505_Subscription_Data_Templates all;
+import from TS29512_Npcf_SMPolicyControl all;
+import from TS29512_Npcf_SMPolicyControl_Templates all;
+import from TS29519_Policy_Data all;
+import from TS29519_Policy_Data_Templates all;
+import from TS29521_Nbsf_Management all;
+import from TS29521_Nbsf_Management_Templates all;
+
+import from PCF_Tests all;
+
+const integer HTTP2_CONN_SCP := 0;
+
+/* These are a preset of path matches which can be applied through the entire lifecycle of the session: */
+function f_http2_server_path_match()
+runs on ConnHdlr return charstring {
+ var charstring imsi_match := "*imsi-" & g_pars.imsi_str & "*";
+ return imsi_match;
+}
+
+type record ConnHdlrPars {
+ integer idx,
+ integer pdu_sess_id,
+ hexstring imsi,
+ charstring imsi_str,
+ charstring serving_network,
+ NfInstanceId1 ausf_instance_id,
+ charstring nudm_ueau_auth_event_id optional
+}
+
+type component ConnHdlr extends HTTP2_CT, HTTP2_ConnHdlr, Prometheus_Checker_CT {
+ var ConnHdlrPars g_pars;
+}
+
+type function void_fn() runs on ConnHdlr;
+
+function f_ConnHdlrPars(integer idx := 0) return ConnHdlrPars
+{
+ var hexstring imsi := f_concat_pad(lengthof(mp_imsi), substr(mp_imsi, 0, lengthof(mp_imsi) - 6), idx);
+ var charstring imsi_str := f_dec_TBCD(imsi_hex2oct(imsi));
+ var template (value) ConnHdlrPars pars := {
+ idx := idx,
+ pdu_sess_id := idx + 1,
+ imsi := imsi,
+ imsi_str := imsi_str,
+ serving_network := "5G:mnc070.mcc999.3gppnetwork.org", /* TODO: set based on mp_mcc and mp_mnc */
+ ausf_instance_id := "ausf-instance-id-" & int2str(idx),
+ nudm_ueau_auth_event_id := omit
+ };
+ return valueof(pars);
+}
+
+function f_ConnHdlr_init(void_fn fn, ConnHdlrPars pars) runs on ConnHdlr {
+ /* make parameters available via component variable */
+ g_pars := pars;
+
+ /* Setup */
+ /* Register SCP HTTP2 sever, where IUT will send all SBI requests: */
+ f_http2_server_emu_register(f_http2_server_path_match(), idx := HTTP2_CONN_SCP);
+ f_http2_adapter_init();
+
+ fn.apply();
+
+ /* Cleanup */
+ f_http2_server_emu_unregister(f_http2_server_path_match(), idx := HTTP2_CONN_SCP);
+}
+
+function f_http2_adapter_connect_pcf(integer idx := 0)
+runs on ConnHdlr {
+ f_http2_adapter_connect(mp_pcf_hostname, mp_pcf_sbi_port, mp_smf_local_ip, idx := idx);
+}
+
+function f_http2_adapter_connect_send_pcf(template (value) HTTP2_Msg http2_msg, integer idx := 0)
+runs on ConnHdlr {
+ f_http2_adapter_connect_pcf(idx := idx);
+ f_http2_adapter_send(http2_msg);
+}
+
+/********************************************
+ * SCP
+/*******************************************/
+const charstring SCP_uri_hostport := mp_scp_local_ip & ":" & int2str(mp_scp_local_port);
+const charstring SCP_uri_prefix := "http://" & SCP_uri_hostport;
+
+/****************************************************
+ * N7 NPcf (SBI): Emulated SMF, 3GPP TS 29.512
+ ****************************************************/
+const charstring c_Npcf_uri_hostport := mp_pcf_hostname & ":" & int2str(mp_pcf_sbi_port);
+const charstring c_Npcf_uri_prefix := "http://" & c_Npcf_uri_hostport;
+
+function f_ts_PlmnIdNid1()
+runs on ConnHdlr return TS29512_Npcf_SMPolicyControl.PlmnIdNid1 {
+ return valueof(TS29512_Npcf_SMPolicyControl_Templates.ts_PlmnIdNid1("001", "001"));
+}
+
+/* 3GPP TS 29.512 5.3.2.3.1 Resource: SM Policies (POST) */
+private function f_n13_prepare_sm_policies(SmPolicyContextData1 ctx_data)
+runs on ConnHdlr return HTTP2_Msg {
+ var octetstring ctx_data_enc;
+ var integer http2_idx;
+ var integer http2_stream_id;
+ var template (value) HTTP2_Msg http2_tx;
+
+ ctx_data_enc := f_enc_SmPolicyContextData1(ctx_data);
+
+ http2_idx := f_http2_adapter_find_free_idx();
+ http2_stream_id := f_http2_adapter_next_stream_id(http2_idx);
+ http2_tx := ts_HTTP2_Msg(http2_idx,
+ http2_stream_id,
+ hb := {
+ pseudo_headers := ts_HTTP2_pseudo_headers_Req(method := "POST",
+ scheme := "http",
+ authority := c_Npcf_uri_hostport,
+ path := c_Npcf_SMPolicyControl_path_sm_policies),
+ headers := {
+ ts_HTTP2_Hdr_content_type("application/json"),
+ ts_HTTP2_Hdr_accept("application/json"),
+ ts_HTTP2_Hdr_user_agent("ttcn3-smf"),
+ ts_HTTP2_Hdr_accept_encoding("gzip")
+ }
+ },
+ body := ts_HTTP2_Data_frame(http2_stream_id,
+ end_stream_flag := true,
+ data := ctx_data_enc));
+ return valueof(http2_tx);
+}
+
+/* 3GPP TS 29.512 5.3.2 Resource: SM Policies (POST) */
+function f_n7_sm_policies()
+runs on ConnHdlr {
+ var HTTP2_Msg http2_tx;
+ var HTTP2_Msg http2_rx;
+ var template (present) HTTP2_Msg http2_exp_rx;
+ var template (value) SmPolicyContextData1 ctx_data;
+
+ ctx_data := ts_SmPolicyContextData1(supi := ts_sbi_Supi(g_pars.imsi_str),
+ pduSessionId := g_pars.pdu_sess_id,
+ pduSessionType := ts_PduSessionType1(IPV4),
+ dnn := "internet",
+ notificationUri := ts_Nsmf_Callback_uri_sm_policy_notify(int2str(g_pars.pdu_sess_id)),
+ servingNetwork := f_ts_PlmnIdNid1(),
+ ipv4Address := "10.45.0.2",
+ sliceInfo := TS29512_Npcf_SMPolicyControl_Templates.ts_Snssai1(1));
+
+ http2_tx := f_n13_prepare_sm_policies(valueof(ctx_data));
+ f_http2_adapter_connect_send_pcf(http2_tx, idx := http2_tx.conn_id);
+
+ /* BSF: Register to rx generic path.
+ * Note: This will need a Mutex if f_n7_sm_policies() is to be called concurrently. */
+ f_http2_server_emu_register(c_Nbsf_Management_path_pcfBindings, idx := HTTP2_CONN_SCP);
+
+ /* Expect UDR to receive GET sm-data: */
+ as_nudr_DR_policy_data_get_sm_data();
+
+ /* Expect BSF to receive registration from PCF for this PDU session: */
+ as_Nbsf_Management_post_pcfbinding();
+ f_http2_server_emu_unregister(c_Nbsf_Management_path_pcfBindings, idx := HTTP2_CONN_SCP);
+
+ /* 3GPP TS 29.512 Table 5.3.2.3.1-3 */
+ http2_exp_rx :=
+ tr_HTTP2_Msg(http2_tx.conn_id,
+ http2_tx.stream_id,
+ tr_HTTP2_header_block(pseudo_headers := tr_HTTP2_pseudo_headers_Resp(201)),
+ tr_HTTP2_Data_frame(stream_id := http2_tx.stream_id,
+ end_stream_flag := true,
+ data := decmatch tr_SmPolicyDecision1));
+ as_http2_adapter_receive(http2_rx, http2_exp_rx, idx := http2_tx.conn_id);
+
+ f_http2_adapter_close(idx := http2_tx.conn_id);
+ setverdict(pass);
+}
+
+
+/************************************************************************************
+ * N35 Nudr_DataRepository (SBI): Emulated UDR, 3GPP TS 29.504, 3GPP TS 29.505 A.2
+ ************************************************************************************/
+function f_tr_Nudr_DR_policy_data_get_sm_data()
+runs on ConnHdlr return template (present) HTTP2_Msg {
+ var template (present) HTTP2_Msg http2_msg;
+ var template (present) HTTP2_header_block hb;
+ var template (present) HTTP2_pseudo_headers pseudo_headers;
+ var template HTTP2_header_list headers := *;
+
+ pseudo_headers := tr_HTTP2_pseudo_headers_Req(method := "GET",
+ path := tr_Nudr_DR_policy_data_path_sm_data(g_pars.imsi_str));
+ hb := tr_HTTP2_header_block(pseudo_headers, headers);
+ http2_msg := tr_HTTP2_Msg(?, ?, hb := hb, body := omit);
+ return http2_msg;
+}
+
+altstep as_nudr_DR_policy_data_get_sm_data()
+runs on ConnHdlr {
+ var HTTP2_Msg http2_rx;
+ [] HTTP2_CONN[HTTP2_CONN_SCP].receive(f_tr_Nudr_DR_policy_data_get_sm_data()) -> value http2_rx {
+ var template (value) SmPolicyData sm_policy_data;
+ var octetstring body_enc;
+ var template (value) HTTP2_Msg http2_tx;
+
+ sm_policy_data := ts_SmPolicyData(smPolicySnssaiData := {
+ {"", ts_SmPolicySnssaiData(snssai := ts_Snssai(1),
+ smPolicyDnnData := {{"internet",
+ ts_SmPolicyDnnData(dnn := "internet")}})}
+ });
+ body_enc := f_enc_SmPolicyData(valueof(sm_policy_data));
+
+ http2_tx := ts_HTTP2_Msg_200_OK(http2_rx.conn_id,
+ http2_rx.stream_id,
+ headers := {
+ ts_HTTP2_Hdr_content_type("application/json; charset=utf-8")
+ },
+ body := ts_HTTP2_Data_frame(http2_rx.stream_id,
+ end_stream_flag := true,
+ data := body_enc));
+ HTTP2_CONN[HTTP2_CONN_SCP].send(http2_tx);
+ setverdict(pass);
+ }
+}
+
+/************************************************************************************
+ * Nbsf_Management (SBI): Emulated BSF, 3GPP TS 29.521
+ ************************************************************************************/
+const charstring c_Nbsf_uri_hostport := SCP_uri_hostport;
+const charstring c_Nbsf_uri_prefix := "http://" & c_Nbsf_uri_hostport;
+
+template (value) charstring
+ts_Nbsf_Management_uri_individual_pcf_pdu_sess_binding(template (value) charstring binding_id)
+:= c_Nbsf_uri_prefix & "/" & valueof(ts_Nbsf_Management_path_individual_pcf_pdu_sess_binding(binding_id));
+
+/* 5.3.2.3.1 Resource: PCF for a PDU Session Bindings (POST) */
+function f_tr_Nbsf_Management_post_pcfbinding()
+runs on ConnHdlr return template (present) HTTP2_Msg {
+ var template (present) HTTP2_Msg http2_msg;
+ var template (present) HTTP2_header_block hb;
+ var template (present) HTTP2_pseudo_headers pseudo_headers;
+ var template HTTP2_header_list headers := *;
+
+ pseudo_headers := tr_HTTP2_pseudo_headers_Req(method := "POST",
+ path := c_Nbsf_Management_path_pcfBindings);
+ hb := tr_HTTP2_header_block(pseudo_headers, headers);
+ http2_msg := tr_HTTP2_Msg(?, ?,
+ hb := hb,
+ body := tr_HTTP2_Data_frame(data := decmatch tr_PcfBinding));
+ return http2_msg;
+}
+
+
+/* 4.2.2.2 Register a new PCF for a PDU Session binding information */
+altstep as_Nbsf_Management_post_pcfbinding()
+runs on ConnHdlr {
+ var HTTP2_Msg http2_rx;
+ [] HTTP2_CONN[HTTP2_CONN_SCP].receive(f_tr_Nbsf_Management_post_pcfbinding()) -> value http2_rx {
+ var PcfBinding pcf_binding;
+ var octetstring body_enc;
+ var template (value) HTTP2_Msg http2_tx;
+
+ f_dec_PcfBinding(http2_rx.body.data, pcf_binding); // TODO: check rc
+
+ body_enc := f_enc_PcfBinding(pcf_binding);
+
+ http2_tx := ts_HTTP2_Msg_201_Created(http2_rx.conn_id,
+ http2_rx.stream_id,
+ headers := {
+ ts_HTTP2_Hdr_content_type("application/json; charset=utf-8"),
+ ts_HTTP2_Hdr_location(ts_Nbsf_Management_uri_individual_pcf_pdu_sess_binding(g_pars.imsi_str))
+ },
+ body := ts_HTTP2_Data_frame(http2_rx.stream_id,
+ end_stream_flag := true,
+ data := body_enc));
+ HTTP2_CONN[HTTP2_CONN_SCP].send(http2_tx);
+ setverdict(pass);
+ }
+}
+
+/************************************************************
+ * N17 Nsmf (SBI): Emulated SMF, 3GPP TS 29.502
+ ************************************************************/
+const charstring c_Nsmf_uri_hostport := SCP_uri_hostport;
+const charstring c_Nsmf_uri_prefix := "http://" & c_Nsmf_uri_hostport;
+const charstring c_Nsmf_Callback_path_api_prefix := "/nsmf-callback/v1";
+
+template (value) charstring
+ts_Nsmf_Callback_uri_sm_policy_notify(template (value) charstring id)
+:= c_Nsmf_uri_prefix & c_Nsmf_Callback_path_api_prefix & "/sm-policy-notify/" & valueof(id);
+
+
+}
diff --git a/pcf/PCF_Tests.cfg b/pcf/PCF_Tests.cfg
new file mode 100644
index 0000000..ce12035
--- /dev/null
+++ b/pcf/PCF_Tests.cfg
@@ -0,0 +1,23 @@
+[ORDERED_INCLUDE]
+# Common configuration, shared between test suites
+"../Common.cfg"
+# testsuite specific configuration, not expected to change
+"./PCF_Tests.default"
+
+# Local configuration below
+
+[LOGGING]
+
+[TESTPORT_PARAMETERS]
+
+[MODULE_PARAMETERS]
+PCF_Tests.mp_pcf_hostname := "127.0.0.13";
+PCF_Tests.mp_pcf_sbi_port := 7777;
+PCF_Tests.mp_scp_local_ip := "127.0.0.200";
+PCF_Tests.mp_scp_local_port := 7777;
+PCF_Tests.mp_smf_local_ip := "127.0.0.6";
+
+[MAIN_CONTROLLER]
+
+[EXECUTE]
+PCF_Tests.control
diff --git a/pcf/PCF_Tests.default b/pcf/PCF_Tests.default
new file mode 100644
index 0000000..b03f59e
--- /dev/null
+++ b/pcf/PCF_Tests.default
@@ -0,0 +1,12 @@
+[LOGGING]
+FileMask := LOG_ALL | TTCN_DEBUG | TTCN_MATCHING | DEBUG_ENCDEC;
+
+[TESTPORT_PARAMETERS]
+*.TCP.noDelay := "yes" // turn off nagle
+*.HTTP.use_notification_ASPs := "yes"
+
+[MODULE_PARAMETERS]
+
+[MAIN_CONTROLLER]
+
+[EXECUTE]
diff --git a/pcf/PCF_Tests.ttcn b/pcf/PCF_Tests.ttcn
new file mode 100644
index 0000000..8750bf8
--- /dev/null
+++ b/pcf/PCF_Tests.ttcn
@@ -0,0 +1,135 @@
+/* PCF test suite in TTCN-3 (3GPP TS 29.512)
+ * (C) 2026 by sysmocom - s.f.m.c. GmbH <info@sysmocom.de>
+ * All rights reserved.
+ * Author: Pau Espin Pedrol <pespin@sysmocom.de>
+ *
+ * Released under the terms of GNU General Public License, Version 2 or
+ * (at your option) any later version.
+ *
+ * SPDX-License-Identifier: GPL-2.0-or-later
+ */
+
+module PCF_Tests {
+
+import from General_Types all;
+import from Native_Functions all;
+import from IPL4asp_Types all;
+import from Misc_Helpers all;
+
+import from Osmocom_Types all;
+import from GSM_Types all;
+
+import from TCCEncoding_Functions all;
+
+import from HTTP2_Adapter all;
+import from HTTP2_Server_Emulation all;
+
+import from ConnHdlr all;
+
+modulepar {
+ charstring mp_pcf_hostname := "127.0.0.13";
+ integer mp_pcf_sbi_port := 7777;
+
+ charstring mp_scp_local_ip := "127.0.0.200";
+ integer mp_scp_local_port := 7777;
+
+ /* IP address at which we listen for HTTP2/SBI to emulate a AUSF in ttcn3 */
+ charstring mp_smf_local_ip := "127.0.0.6";
+
+ GsmMcc mp_mcc := '999'H;
+ GsmMnc mp_mnc := '70'H;
+ HEX15n mp_imsi := '999700000000000'H;
+}
+
+type component MTC_CT extends HTTP2_CT, HTTP2_ConnHdlr {
+ /* emulated SCP */
+ var HTTP2_Server_Emulation_CT vc_HTTP2_SRV_SCP;
+
+ timer g_Tguard := 30.0;
+}
+
+private function f_init_http2_srv(charstring id) runs on MTC_CT {
+ id := id & "-HTTP2SRV";
+
+ var Http2ServerEmulationCfg http2_srv_cfg := {
+ http2_bind_ip := mp_scp_local_ip,
+ http2_bind_port := mp_scp_local_port,
+ one_req_per_conn := false
+ };
+
+ vc_HTTP2_SRV_SCP := HTTP2_Server_Emulation_CT.create(id) alive;
+ vc_HTTP2_SRV_SCP.start(HTTP2_Server_Emulation.main(http2_srv_cfg));
+
+ connect(self:HTTP2_CONN_PROC[HTTP2_CONN_SCP], vc_HTTP2_SRV_SCP:CONN_PROC);
+}
+
+
+private function f_init(integer imsi_suffix := 0, float t_guard := 30.0) runs on MTC_CT {
+ var charstring id := testcasename();
+
+ g_Tguard.start(t_guard);
+ activate(as_Tguard());
+
+ f_init_http2_srv(id);
+}
+
+private function f_shutdown() runs on MTC_CT {
+ f_http2_server_close_conn_all();
+ setverdict(pass);
+}
+
+private function f_start_handler_create()
+runs on MTC_CT return ConnHdlr
+{
+ var ConnHdlr vc_conn;
+ var charstring id := testcasename();
+
+ vc_conn := ConnHdlr.create(id);
+
+ if (isbound(vc_HTTP2_SRV_SCP)) {
+ connect(vc_conn:HTTP2_CONN[HTTP2_CONN_SCP], vc_HTTP2_SRV_SCP:CONN);
+ connect(vc_conn:HTTP2_CONN_PROC[HTTP2_CONN_SCP], vc_HTTP2_SRV_SCP:CONN_PROC);
+ }
+
+ return vc_conn;
+}
+
+private function f_start_handler_run(ConnHdlr vc_conn, void_fn fn, ConnHdlrPars pars) runs on MTC_CT
+{
+ vc_conn.start(f_ConnHdlr_init(fn, pars));
+}
+
+/* start a connection handler with given parameters */
+private function f_start_handler(void_fn fn, ConnHdlrPars pars)
+runs on MTC_CT return ConnHdlr {
+ var ConnHdlr vc_conn;
+ vc_conn := f_start_handler_create();
+ f_start_handler_run(vc_conn, fn, pars);
+ return vc_conn;
+}
+
+private altstep as_Tguard() runs on MTC_CT {
+ [] g_Tguard.timeout {
+ Misc_Helpers.f_shutdown(__BFILE__, __LINE__, fail, "Tguard timeout");
+ }
+}
+
+/* 3GPP TS 29.512 5.3.2 Resource: SM Policies */
+private function f_TC_sm_policies() runs on ConnHdlr {
+ f_n7_sm_policies();
+ setverdict(pass);
+}
+testcase TC_sm_policies() runs on MTC_CT {
+ var ConnHdlr vc_conn;
+ var ConnHdlrPars pars := f_ConnHdlrPars(0);
+ f_init();
+ vc_conn := f_start_handler(refers(f_TC_sm_policies), pars);
+ vc_conn.done;
+ f_shutdown();
+}
+
+control {
+ execute( TC_sm_policies() );
+}
+
+}
diff --git a/pcf/README.md b/pcf/README.md
new file mode 100644
index 0000000..ddb8c98
--- /dev/null
+++ b/pcf/README.md
@@ -0,0 +1,18 @@
+# PCF_Tests.ttcn
+
+* external interfaces
+ * N7: SBI (emulates SMF)
+ * N15: SBI (emulates AMF)
+ * N36: SBI (emulates UDR)
+
+{% dot pcf_tests.svg
+digraph G {
+ rankdir=LR;
+ ATS [label="ATS\nPCF_Tests.ttcn"];
+ UDM [label="AMF\open5gs-pcfd",shape="box"];
+
+ ATS -> UDM [label="N7"];
+ ATS -> UDM [label="N15"];
+ ATS -> UDM [label="N36"];
+}
+%}
diff --git a/pcf/create_test_subscribers.sh b/pcf/create_test_subscribers.sh
new file mode 100755
index 0000000..715d66d
--- /dev/null
+++ b/pcf/create_test_subscribers.sh
@@ -0,0 +1,31 @@
+#!/bin/sh -ex
+DB_URI="mongodb://127.0.0.103/open5gs"
+DBCTL_CMD="open5gs-dbctl --db_uri=$DB_URI"
+
+# mongod needs some time to bootstrap...
+while ! mongosh --quiet $DB_URI</dev/null; do
+ sleep 1
+done
+
+NUM_SUBCRS=1
+get_subscr_imsi() {
+ subscr_idx=$1
+ printf "999700000000%03u" "$subscr_idx"
+}
+
+# Create a test subscriber with IMSI=001010000000000
+DBCTL_PARALLEL_JOBS=20
+idx=0
+while test "$idx" -lt "$NUM_SUBCRS"; do
+ remain="$((NUM_SUBCRS - idx))"
+ if test "$remain" -gt "$DBCTL_PARALLEL_JOBS"; then
+ iterations=$DBCTL_PARALLEL_JOBS
+ else
+ iterations=$remain
+ fi
+ for it in $(seq "$iterations"); do
+ $DBCTL_CMD add "$(get_subscr_imsi $idx)" 3c6e0b8a9c15224a8228b9a98ca1531d 762a2206fe0b4151ace403c86a11e479 &
+ idx=$((idx + 1))
+ done
+ wait $(jobs -p)
+done
diff --git a/pcf/expected-results.xml b/pcf/expected-results.xml
new file mode 100644
index 0000000..dcc5689
--- /dev/null
+++ b/pcf/expected-results.xml
@@ -0,0 +1,4 @@
+<?xml version="1.0"?>
+<testsuite name='Titan' tests='1' failures='0' errors='0' skipped='0' inconc='0' time='MASKED'>
+ <testcase classname='PCF_Tests' name='TC_sm_policies' time='MASKED'/>
+</testsuite>
diff --git a/pcf/gen_links.sh b/pcf/gen_links.sh
new file mode 100755
index 0000000..c14a989
--- /dev/null
+++ b/pcf/gen_links.sh
@@ -0,0 +1,52 @@
+#!/bin/bash -e
+
+BASEDIR=../deps
+
+. ../_buildsystem/gen_links.inc.sh
+
+DIR=$BASEDIR/titan.Libraries.TCCUsefulFunctions/src
+FILES="TCCInterface_Functions.ttcn TCCConversion_Functions.ttcn TCCConversion.cc TCCInterface.cc TCCInterface_ip.h"
+FILES+=" TCCEncoding_Functions.ttcn TCCEncoding.cc " # GSM 7-bit coding
+gen_links $DIR $FILES
+
+DIR=$BASEDIR/titan.TestPorts.Common_Components.Socket-API/src
+FILES="Socket_API_Definitions.ttcn"
+gen_links $DIR $FILES
+
+# Required by MGCP and IPA
+DIR=$BASEDIR/titan.TestPorts.IPL4asp/src
+FILES="IPL4asp_Functions.ttcn IPL4asp_PT.cc IPL4asp_PT.hh IPL4asp_PortType.ttcn IPL4asp_Types.ttcn IPL4asp_discovery.cc IPL4asp_protocol_L234.hh"
+gen_links $DIR $FILES
+
+# Needed by HTTP_Adapter (Prometheus_Checker.ttcn metrics):
+DIR=$BASEDIR/titan.TestPorts.Common_Components.Abstract_Socket/src
+FILES="Abstract_Socket.cc Abstract_Socket.hh "
+gen_links $DIR $FILES
+
+# Needed by HTTP_Adapter (Prometheus_Checker.ttcn metrics):
+DIR=$BASEDIR/titan.TestPorts.HTTPmsg/src
+FILES="HTTPmsg_MessageLen.ttcn HTTPmsg_MessageLen_Function.cc HTTPmsg_PT.cc HTTPmsg_PT.hh HTTPmsg_PortType.ttcn HTTPmsg_Types.ttcn "
+gen_links $DIR $FILES
+
+# Needed by HTTP2_Adapter:
+DIR=$BASEDIR/titan.ProtocolModules.HTTP2/src
+FILES="HTTP2_EncDec.cc HTTP2_Types.ttcn"
+gen_links $DIR $FILES
+
+DIR=$BASEDIR/titan.ProtocolModules.JSON_v07_2006/src
+FILES="JSON_Generic_Null_Def.asn JSON_Generic.ttcn"
+gen_links $DIR $FILES
+
+DIR=$BASEDIR/osmo-ttcn3-openapi-generator/openapi-specs/3GPP_5GC_Rel19/ttcn3
+FILES="TS29571_CommonData.ttcn TS29505_Subscription_Data.ttcn TS29512_Npcf_SMPolicyControl.ttcn TS29519_Policy_Data.ttcn TS29521_Nbsf_Management.ttcn "
+gen_links $DIR $FILES
+
+DIR=../library
+FILES="Misc_Helpers.ttcn General_Types.ttcn GSM_Types.ttcn Osmocom_Types.ttcn Native_Functions.ttcn Native_FunctionDefs.cc IPCP_Types.ttcn IPCP_Templates.ttcn "
+FILES+="SCTP_Templates.ttcn "
+FILES+="HTTP2_CodecPort.ttcn HTTP2_CodecPort_CtrlFunct.ttcn HTTP2_CodecPort_CtrlFunctDef.cc HTTP2_Templates.ttcn HTTP2_Functions.ttcn HTTP2_Msg.ttcn HTTP2_Adapter.ttcn HTTP2_Server_Emulation.ttcn "
+FILES+="HTTP_Adapter.ttcn Prometheus_Checker.ttcn "
+FILES+="TS29571_CommonData_Templates.ttcn TS29505_Subscription_Data_Templates.ttcn TS29512_Npcf_SMPolicyControl_Templates.ttcn TS29519_Policy_Data_Templates.ttcn TS29521_Nbsf_Management_Templates.ttcn "
+gen_links $DIR $FILES
+
+gen_links_finish
diff --git a/pcf/mongod.conf b/pcf/mongod.conf
new file mode 100644
index 0000000..ff648f4
--- /dev/null
+++ b/pcf/mongod.conf
@@ -0,0 +1,45 @@
+# mongod.conf
+
+# for documentation of all options, see:
+# http://docs.mongodb.org/manual/reference/configuration-options/
+
+# Where and how to store data.
+storage:
+ dbPath: db
+# journal:
+# enabled: true
+# engine:
+# mmapv1:
+# wiredTiger:
+
+# where to write logging data.
+# systemLog:
+# destination: file
+# logAppend: true
+# path: /data/mongod.log
+
+# network interfaces
+net:
+ port: 27017
+ bindIp: 127.0.0.103
+
+
+# how the process runs
+processManagement:
+ timeZoneInfo: /usr/share/zoneinfo
+
+#security:
+
+#operationProfiling:
+
+#replication:
+
+#sharding:
+
+## Enterprise-Only Options:
+
+#auditLog:
+
+#snmp:
+
+
diff --git a/pcf/open5gs-pcf.yaml b/pcf/open5gs-pcf.yaml
new file mode 100644
index 0000000..5a8ecfa
--- /dev/null
+++ b/pcf/open5gs-pcf.yaml
@@ -0,0 +1,24 @@
+# See https://github.com/open5gs/open5gs/blob/main/configs/open5gs/pcf.yaml.in
+
+db_uri: mongodb://127.0.0.103/open5gs
+logger:
+ level: debug
+
+global:
+ max:
+ ue: 1024
+
+pcf:
+ sbi:
+ server:
+ - address: 127.0.0.13
+ port: 7777
+ client:
+# nrf:
+# - uri: http://127.0.0.10:7777
+ scp:
+ - uri: http://127.0.0.200:7777
+ metrics:
+ server:
+ - address: 127.0.0.13
+ port: 9090
diff --git a/pcf/regen_makefile.sh b/pcf/regen_makefile.sh
new file mode 100755
index 0000000..6430bdd
--- /dev/null
+++ b/pcf/regen_makefile.sh
@@ -0,0 +1,23 @@
+#!/bin/sh -e
+
+NAME=PCF_Tests
+
+FILES="
+ *.asn
+ *.ttcn
+ Abstract_Socket.cc
+ HTTPmsg_MessageLen_Function.cc
+ HTTPmsg_PT.cc
+ HTTP2_EncDec.cc
+ HTTP2_CodecPort_CtrlFunctDef.cc
+ IPL4asp_PT.cc
+ IPL4asp_discovery.cc
+ Native_FunctionDefs.cc
+ TCCConversion.cc
+ TCCEncoding.cc
+ TCCInterface.cc
+"
+
+. ../_buildsystem/regen_makefile.inc.sh
+
+sed -i -e 's/^LINUX_LIBS = -lxml2 -lsctp/LINUX_LIBS = -lxml2 -lsctp -lgnutls/' Makefile
diff --git a/pcf/testenv.cfg b/pcf/testenv.cfg
new file mode 100644
index 0000000..b4dd3cc
--- /dev/null
+++ b/pcf/testenv.cfg
@@ -0,0 +1,19 @@
+[testsuite]
+program=PCF_Tests
+config=PCF_Tests.cfg
+
+[db]
+prepare=mkdir db
+clean=rm -rf db
+program=mongod --config mongod.conf
+setup=create_test_subscribers.sh
+copy=mongod.conf
+make=no
+package=no
+
+[pcf]
+program=open5gs-pcfd -c open5gs-pcf.yaml
+make=open5gs
+package=open5gs-pcf
+copy=open5gs-pcf.yaml
+
diff --git a/pcf/testsrcdir.cfg b/pcf/testsrcdir.cfg
new file mode 100644
index 0000000..7f19289
--- /dev/null
+++ b/pcf/testsrcdir.cfg
@@ -0,0 +1,2 @@
+[testsrcdir]
+max_jobs_per_gb_ram=0.3
diff --git a/smf/SMF_Session_CT_5G.ttcn b/smf/SMF_Session_CT_5G.ttcn
index 791ec7c..d535b53 100644
--- a/smf/SMF_Session_CT_5G.ttcn
+++ b/smf/SMF_Session_CT_5G.ttcn
@@ -773,8 +773,8 @@
var template (value) HTTP2_Msg http2_tx;
var TS29503_Nudm_SDM.PduSessionType1_enum pdu_sess_type := f_pfcp_pdn_type_2_Nudm_SDM_pdu_session_type(g_pars.pfcp_pars.pdn_type);
- dnn_cfg := ts_DnnConfiguration1(pduSessionTypes := ts_PduSessionTypes1(defaultSessionType := ts_PduSessionType1(pdu_sess_type),
- allowedSessionTypes := { ts_PduSessionType1(pdu_sess_type) }),
+ dnn_cfg := ts_DnnConfiguration1(pduSessionTypes := ts_PduSessionTypes1(defaultSessionType := TS29503_Nudm_SDM_Templates.ts_PduSessionType1(pdu_sess_type),
+ allowedSessionTypes := { TS29503_Nudm_SDM_Templates.ts_PduSessionType1(pdu_sess_type) }),
sscModes := ts_SscModes1(defaultSscMode := ts_SscMode1(SSC_MODE_1),
allowedSscModes := { ts_SscMode1(SSC_MODE_1),
ts_SscMode1(SSC_MODE_2),
To view, visit change 44000. To unsubscribe, or for help writing mail filters, visit settings.