pespin submitted this change.
Introduce eir testsuite
Related: SYS#7073
Change-Id: I6aebeef821691569cc8da98dc2297394e8f098c4
---
M Makefile
A eir/ConnHdlr.ttcn
A eir/EIR_Tests.cfg
A eir/EIR_Tests.default
A eir/EIR_Tests.ttcn
A eir/README.md
A eir/create_test_subscribers.sh
A eir/expected-results.xml
A eir/gen_links.sh
A eir/mongod.conf
A eir/open5gs-eir.yaml
A eir/regen_makefile.sh
A eir/testenv.cfg
A eir/testsrcdir.cfg
A library/TS29511_N5g_eir_EquipmentIdentityCheck_Templates.ttcn
15 files changed, 736 insertions(+), 0 deletions(-)
diff --git a/Makefile b/Makefile
index df8319e..544cbaa 100644
--- a/Makefile
+++ b/Makefile
@@ -27,6 +27,7 @@
ccid \
dia2gsup \
eim \
+ eir \
fr \
fr-net \
epdg \
diff --git a/eir/ConnHdlr.ttcn b/eir/ConnHdlr.ttcn
new file mode 100644
index 0000000..d4616e5
--- /dev/null
+++ b/eir/ConnHdlr.ttcn
@@ -0,0 +1,182 @@
+/* EIR test suite in TTCN-3 (3GPP TS 29.511), ConnHdlr
+ * (C) 2026 by sysmocom - s.f.m.c. GmbH <info@sysmocom.de>
+ * All rights reserved.
+ * Author: Pau Espin Pedrol <pespin@sysmocom.de>
+ *
+ * Released under the terms of GNU General Public License, Version 2 or
+ * (at your option) any later version.
+ *
+ * SPDX-License-Identifier: GPL-2.0-or-later
+ */
+
+module ConnHdlr {
+
+import from TCCEncoding_Functions all;
+
+import from General_Types all;
+import from Native_Functions all;
+import from IPL4asp_Types all;
+import from Misc_Helpers all;
+
+import from Osmocom_Types all;
+import from GSM_Types all;
+
+import from HTTP2_Types all;
+import from HTTP2_Templates all;
+import from HTTP2_Functions all;
+import from HTTP2_Msg all;
+import from HTTP2_Adapter all;
+import from HTTP2_Server_Emulation all;
+
+import from Prometheus_Checker all;
+
+import from TS29511_N5g_eir_EquipmentIdentityCheck all;
+import from TS29511_N5g_eir_EquipmentIdentityCheck_Templates all;
+
+import from EIR_Tests all;
+
+const integer HTTP2_CONN_SCP := 0;
+
+/* These are a preset of path matches which can be applied through the entire lifecycle of the session: */
+function f_http2_server_path_match()
+runs on ConnHdlr return charstring {
+ var charstring imsi_match := "*imei-" & g_pars.imei_str & "*";
+ return imsi_match;
+}
+
+type record ConnHdlrPars {
+ integer idx,
+ hexstring imsi,
+ charstring imsi_str,
+ hexstring imei,
+ charstring imei_str
+}
+
+type component ConnHdlr extends HTTP2_CT, HTTP2_ConnHdlr, Prometheus_Checker_CT {
+ var ConnHdlrPars g_pars;
+}
+
+type function void_fn() runs on ConnHdlr;
+
+function f_ConnHdlrPars(integer idx := 0) return ConnHdlrPars
+{
+ var hexstring imsi := f_concat_pad(lengthof(mp_imsi), substr(mp_imsi, 0, lengthof(mp_imsi) - 6), idx);
+ var charstring imsi_str := f_dec_TBCD(imsi_hex2oct(imsi));
+ var hexstring imei := f_concat_pad(lengthof(mp_imei), substr(mp_imei, 0, lengthof(mp_imei) - 6), idx);
+ var charstring imei_str := f_dec_TBCD(imsi_hex2oct(imei));
+ var template (value) ConnHdlrPars pars := {
+ idx := idx,
+ imsi := imsi,
+ imsi_str := imsi_str,
+ imei := imei,
+ imei_str := imei_str
+ };
+ return valueof(pars);
+}
+
+function f_ConnHdlr_init(void_fn fn, ConnHdlrPars pars) runs on ConnHdlr {
+ /* make parameters available via component variable */
+ g_pars := pars;
+
+ /* Setup */
+ /* Register SCP HTTP2 sever, where IUT will send all SBI requests: */
+ f_http2_server_emu_register(f_http2_server_path_match(), idx := HTTP2_CONN_SCP);
+ f_http2_adapter_init();
+
+ fn.apply();
+
+ /* Cleanup */
+ f_http2_server_emu_unregister(f_http2_server_path_match(), idx := HTTP2_CONN_SCP);
+}
+
+function f_http2_adapter_connect_eir(integer idx := 0)
+runs on ConnHdlr {
+ f_http2_adapter_connect(mp_eir_hostname, mp_eir_sbi_port, mp_amf_local_ip, idx := idx);
+}
+
+function f_http2_adapter_connect_send_eir(template (value) HTTP2_Msg http2_msg, integer idx := 0)
+runs on ConnHdlr {
+ f_http2_adapter_connect_eir(idx := idx);
+ f_http2_adapter_send(http2_msg);
+}
+
+/********************************************
+ * SCP
+/*******************************************/
+const charstring c_SCP_uri_hostport := mp_scp_local_ip & ":" & int2str(mp_scp_local_port);
+const charstring c_SCP_uri_prefix := "http://" & c_SCP_uri_hostport;
+
+/***********************************************************************
+ * N17 N5g-eir_EquipmentIdentityCheck (SBI): Emulated AMF, 3GPP TS 29.511
+ ***********************************************************************/
+const charstring c_N5g_eir_uri_hostport := mp_eir_hostname & ":" & int2str(mp_eir_sbi_port);
+const charstring c_N5g_eir_uri_prefix := "http://" & c_N5g_eir_uri_hostport;
+
+/* 3GPP TS 29.511 6.1.3.2 Resource: equipmentStatus (GET) */
+private function f_n17_prepare_get_equipment_status(EquipmentStatusParameters eq_status_param)
+runs on ConnHdlr return HTTP2_Msg {
+ var charstring path;
+ var integer http2_idx;
+ var integer http2_stream_id;
+ var template (value) HTTP2_Msg http2_tx;
+
+ path := c_N5g_eir_eic_path_equipment_status &
+ f_enc_EquipmentStatusParameters(eq_status_param);
+
+ http2_idx := f_http2_adapter_find_free_idx();
+ http2_stream_id := f_http2_adapter_next_stream_id(http2_idx);
+ http2_tx := ts_HTTP2_Msg(http2_idx,
+ http2_stream_id,
+ hb := {
+ pseudo_headers := ts_HTTP2_pseudo_headers_Req(method := "GET",
+ scheme := "http",
+ authority := c_N5g_eir_uri_hostport,
+ path := path),
+ headers := {
+ ts_HTTP2_Hdr_content_type("application/json"),
+ ts_HTTP2_Hdr_accept("application/json"),
+ ts_HTTP2_Hdr_user_agent("ttcn3-ausf"),
+ ts_HTTP2_Hdr_accept_encoding("gzip")
+ }
+ },
+ body := omit);
+ return valueof(http2_tx);
+}
+
+/* 3GPP TS 29.511 6.1.3.2 Resource: equipmentStatus (GET) */
+function f_n17_get_equipment_status(template (value) EquipmentStatusParameters eq_status_param,
+ template (present) EquipmentStatus status := ?,
+ boolean exp_found := true)
+runs on ConnHdlr {
+ var HTTP2_Msg http2_tx;
+ var HTTP2_Msg http2_rx;
+ var template (present) HTTP2_Msg http2_exp_rx;
+
+ http2_tx := f_n17_prepare_get_equipment_status(valueof(eq_status_param));
+ f_http2_adapter_connect_send_eir(http2_tx, idx := http2_tx.conn_id);
+
+ /* 3GPP TS 29.511 Table 6.1.3.2.3.1-3 */
+ if (exp_found) {
+ http2_exp_rx :=
+ tr_HTTP2_Msg(http2_tx.conn_id,
+ http2_tx.stream_id,
+ tr_HTTP2_header_block(pseudo_headers := tr_HTTP2_pseudo_headers_Resp(200)),
+ tr_HTTP2_Data_frame(stream_id := http2_tx.stream_id,
+ end_stream_flag := true,
+ data := decmatch tr_EirResponseData(status)));
+ } else {
+ http2_exp_rx :=
+ tr_HTTP2_Msg(http2_tx.conn_id,
+ http2_tx.stream_id,
+ tr_HTTP2_header_block(pseudo_headers := tr_HTTP2_pseudo_headers_Resp(404)),
+ tr_HTTP2_Data_frame(stream_id := http2_tx.stream_id,
+ end_stream_flag := true,
+ data := ? /* TODO: Parse applications/problem+json cause=ERROR_EQUIPMENT_UNKNOWN*/));
+ }
+ as_http2_adapter_receive(http2_rx, http2_exp_rx, idx := http2_tx.conn_id);
+
+ f_http2_adapter_close(idx := http2_tx.conn_id);
+ setverdict(pass);
+}
+
+}
diff --git a/eir/EIR_Tests.cfg b/eir/EIR_Tests.cfg
new file mode 100644
index 0000000..59369b8
--- /dev/null
+++ b/eir/EIR_Tests.cfg
@@ -0,0 +1,23 @@
+[ORDERED_INCLUDE]
+# Common configuration, shared between test suites
+"../Common.cfg"
+# testsuite specific configuration, not expected to change
+"./EIR_Tests.default"
+
+# Local configuration below
+
+[LOGGING]
+
+[TESTPORT_PARAMETERS]
+
+[MODULE_PARAMETERS]
+EIR_Tests.mp_eir_hostname := "127.0.0.21";
+EIR_Tests.mp_eir_sbi_port := 7777;
+EIR_Tests.mp_scp_local_ip := "127.0.0.200";
+EIR_Tests.mp_scp_local_port := 7777;
+EIR_Tests.mp_amf_local_ip := "127.0.0.6";
+
+[MAIN_CONTROLLER]
+
+[EXECUTE]
+EIR_Tests.control
diff --git a/eir/EIR_Tests.default b/eir/EIR_Tests.default
new file mode 100644
index 0000000..b03f59e
--- /dev/null
+++ b/eir/EIR_Tests.default
@@ -0,0 +1,12 @@
+[LOGGING]
+FileMask := LOG_ALL | TTCN_DEBUG | TTCN_MATCHING | DEBUG_ENCDEC;
+
+[TESTPORT_PARAMETERS]
+*.TCP.noDelay := "yes" // turn off nagle
+*.HTTP.use_notification_ASPs := "yes"
+
+[MODULE_PARAMETERS]
+
+[MAIN_CONTROLLER]
+
+[EXECUTE]
diff --git a/eir/EIR_Tests.ttcn b/eir/EIR_Tests.ttcn
new file mode 100644
index 0000000..da0dd94
--- /dev/null
+++ b/eir/EIR_Tests.ttcn
@@ -0,0 +1,248 @@
+/* EIR test suite in TTCN-3 (3GPP TS 29.511)
+ * (C) 2026 by sysmocom - s.f.m.c. GmbH <info@sysmocom.de>
+ * All rights reserved.
+ * Author: Pau Espin Pedrol <pespin@sysmocom.de>
+ *
+ * Released under the terms of GNU General Public License, Version 2 or
+ * (at your option) any later version.
+ *
+ * SPDX-License-Identifier: GPL-2.0-or-later
+ */
+
+module EIR_Tests {
+
+import from General_Types all;
+import from Native_Functions all;
+import from IPL4asp_Types all;
+import from Misc_Helpers all;
+
+import from Osmocom_Types all;
+import from GSM_Types all;
+
+import from TCCEncoding_Functions all;
+
+import from HTTP2_Adapter all;
+import from HTTP2_Server_Emulation all;
+
+import from TS29511_N5g_eir_EquipmentIdentityCheck all;
+import from TS29511_N5g_eir_EquipmentIdentityCheck_Templates all;
+
+import from ConnHdlr all;
+
+modulepar {
+ charstring mp_eir_hostname := "127.0.0.21";
+ integer mp_eir_sbi_port := 7777;
+
+ charstring mp_scp_local_ip := "127.0.0.200";
+ integer mp_scp_local_port := 7777;
+
+ /* IP address at which we listen for HTTP2/SBI to emulate a EIR in ttcn3 */
+ charstring mp_amf_local_ip := "127.0.0.6";
+
+ HEX15n mp_imsi := '999700000000000'H;
+ HEX15n mp_imei := '490154203000000'H;
+}
+
+type component MTC_CT extends HTTP2_CT, HTTP2_ConnHdlr {
+ /* emulated SCP */
+ var HTTP2_Server_Emulation_CT vc_HTTP2_SRV_SCP;
+
+ timer g_Tguard := 30.0;
+}
+
+private function f_init_http2_srv(charstring id) runs on MTC_CT {
+ id := id & "-HTTP2SRV";
+
+ var Http2ServerEmulationCfg http2_srv_cfg := {
+ http2_bind_ip := mp_scp_local_ip,
+ http2_bind_port := mp_scp_local_port,
+ one_req_per_conn := false
+ };
+
+ vc_HTTP2_SRV_SCP := HTTP2_Server_Emulation_CT.create(id) alive;
+ vc_HTTP2_SRV_SCP.start(HTTP2_Server_Emulation.main(http2_srv_cfg));
+
+ connect(self:HTTP2_CONN_PROC[HTTP2_CONN_SCP], vc_HTTP2_SRV_SCP:CONN_PROC);
+}
+
+
+private function f_init(float t_guard := 30.0) runs on MTC_CT {
+ var charstring id := testcasename();
+
+ g_Tguard.start(t_guard);
+ activate(as_Tguard());
+
+ f_init_http2_srv(id);
+}
+
+private function f_shutdown() runs on MTC_CT {
+ f_http2_server_close_conn_all();
+ setverdict(pass);
+}
+
+private function f_start_handler_create()
+runs on MTC_CT return ConnHdlr
+{
+ var ConnHdlr vc_conn;
+ var charstring id := testcasename();
+
+ vc_conn := ConnHdlr.create(id);
+
+ if (isbound(vc_HTTP2_SRV_SCP)) {
+ connect(vc_conn:HTTP2_CONN[HTTP2_CONN_SCP], vc_HTTP2_SRV_SCP:CONN);
+ connect(vc_conn:HTTP2_CONN_PROC[HTTP2_CONN_SCP], vc_HTTP2_SRV_SCP:CONN_PROC);
+ }
+
+ return vc_conn;
+}
+
+private function f_start_handler_run(ConnHdlr vc_conn, void_fn fn, ConnHdlrPars pars) runs on MTC_CT
+{
+ vc_conn.start(f_ConnHdlr_init(fn, pars));
+}
+
+/* start a connection handler with given parameters */
+private function f_start_handler(void_fn fn, ConnHdlrPars pars)
+runs on MTC_CT return ConnHdlr {
+ var ConnHdlr vc_conn;
+ vc_conn := f_start_handler_create();
+ f_start_handler_run(vc_conn, fn, pars);
+ return vc_conn;
+}
+
+private altstep as_Tguard() runs on MTC_CT {
+ [] g_Tguard.timeout {
+ Misc_Helpers.f_shutdown(__BFILE__, __LINE__, fail, "Tguard timeout");
+ }
+}
+
+/* 3GPP TS 29.511 5.2.2.2.2 Procedure using CheckEquipmentIdentity Operation */
+private function f_TC_CheckQuipmentIdentity_imei_not_found() runs on ConnHdlr {
+ var template (value) EquipmentStatusParameters query;
+ query := ts_EquipmentStatusParameters(pei := ts_Pei_IMEI(g_pars.imei_str),
+ supi := ts_Supi_IMSI(g_pars.imsi_str));
+ f_n17_get_equipment_status(eq_status_param := query, exp_found := false);
+ setverdict(pass);
+}
+testcase TC_CheckQuipmentIdentity_imei_not_found() runs on MTC_CT {
+ var ConnHdlr vc_conn;
+ var ConnHdlrPars pars := f_ConnHdlrPars(10); /* suffix 10 doesn't exist in EIR DB */
+ f_init();
+ vc_conn := f_start_handler(refers(f_TC_CheckQuipmentIdentity_imei_not_found), pars);
+ vc_conn.done;
+ f_shutdown();
+}
+
+/* 3GPP TS 29.511 5.2.2.2.2 Procedure using CheckEquipmentIdentity Operation */
+private function f_TC_CheckQuipmentIdentity_imei_generic_found_whitelisted() runs on ConnHdlr {
+ var template (value) EquipmentStatusParameters query;
+ query := ts_EquipmentStatusParameters(pei := ts_Pei_IMEI(g_pars.imei_str),
+ supi := ts_Supi_IMSI(g_pars.imsi_str));
+ f_n17_get_equipment_status(eq_status_param := query, status := WHITELISTED);
+ setverdict(pass);
+}
+testcase TC_CheckQuipmentIdentity_imei_generic_found_whitelisted() runs on MTC_CT {
+ var ConnHdlr vc_conn;
+ var ConnHdlrPars pars := f_ConnHdlrPars(0); /* idx: see create_test_subscribers.sh */
+ f_init();
+ vc_conn := f_start_handler(refers(f_TC_CheckQuipmentIdentity_imei_generic_found_whitelisted), pars);
+ vc_conn.done;
+ f_shutdown();
+}
+
+/* 3GPP TS 29.511 5.2.2.2.2 Procedure using CheckEquipmentIdentity Operation */
+private function f_TC_CheckQuipmentIdentity_imei_generic_found_blacklisted() runs on ConnHdlr {
+ var template (value) EquipmentStatusParameters query;
+ query := ts_EquipmentStatusParameters(pei := ts_Pei_IMEI(g_pars.imei_str),
+ supi := ts_Supi_IMSI(g_pars.imsi_str));
+ f_n17_get_equipment_status(eq_status_param := query, status := BLACKLISTED);
+ setverdict(pass);
+}
+testcase TC_CheckQuipmentIdentity_imei_generic_found_blacklisted() runs on MTC_CT {
+ var ConnHdlr vc_conn;
+ var ConnHdlrPars pars := f_ConnHdlrPars(1); /* idx: see create_test_subscribers.sh */
+ f_init();
+ vc_conn := f_start_handler(refers(f_TC_CheckQuipmentIdentity_imei_generic_found_blacklisted), pars);
+ vc_conn.done;
+ f_shutdown();
+}
+
+/* 3GPP TS 29.511 5.2.2.2.2 Procedure using CheckEquipmentIdentity Operation */
+private function f_TC_CheckQuipmentIdentity_imei_generic_found_greylisted() runs on ConnHdlr {
+ var template (value) EquipmentStatusParameters query;
+ query := ts_EquipmentStatusParameters(pei := ts_Pei_IMEI(g_pars.imei_str),
+ supi := ts_Supi_IMSI(g_pars.imsi_str));
+ f_n17_get_equipment_status(eq_status_param := query, status := GREYLISTED);
+ setverdict(pass);
+}
+testcase TC_CheckQuipmentIdentity_imei_generic_found_greylisted() runs on MTC_CT {
+ var ConnHdlr vc_conn;
+ var ConnHdlrPars pars := f_ConnHdlrPars(2); /* idx: see create_test_subscribers.sh */
+ f_init();
+ vc_conn := f_start_handler(refers(f_TC_CheckQuipmentIdentity_imei_generic_found_greylisted), pars);
+ vc_conn.done;
+ f_shutdown();
+}
+
+/* 3GPP TS 29.511 5.2.2.2.2 Procedure using CheckEquipmentIdentity Operation */
+private function f_TC_CheckQuipmentIdentity_imei_specific_supi_found_whitelisted() runs on ConnHdlr {
+ var template (value) EquipmentStatusParameters query;
+ query := ts_EquipmentStatusParameters(pei := ts_Pei_IMEI(g_pars.imei_str),
+ supi := ts_Supi_IMSI(g_pars.imsi_str));
+ f_n17_get_equipment_status(eq_status_param := query, status := WHITELISTED);
+ setverdict(pass);
+}
+testcase TC_CheckQuipmentIdentity_imei_specific_supi_found_whitelisted() runs on MTC_CT {
+ var ConnHdlr vc_conn;
+ var ConnHdlrPars pars := f_ConnHdlrPars(3); /* idx: see create_test_subscribers.sh */
+ f_init();
+ vc_conn := f_start_handler(refers(f_TC_CheckQuipmentIdentity_imei_specific_supi_found_whitelisted), pars);
+ vc_conn.done;
+ f_shutdown();
+}
+
+/* 3GPP TS 29.511 5.2.2.2.2 Procedure using CheckEquipmentIdentity Operation */
+private function f_TC_CheckQuipmentIdentity_imei_specific_supi_found_blacklisted() runs on ConnHdlr {
+ var template (value) EquipmentStatusParameters query;
+ query := ts_EquipmentStatusParameters(pei := ts_Pei_IMEI(g_pars.imei_str),
+ supi := ts_Supi_IMSI(g_pars.imsi_str));
+ f_n17_get_equipment_status(eq_status_param := query, status := BLACKLISTED);
+ setverdict(pass);
+}
+testcase TC_CheckQuipmentIdentity_imei_specific_supi_found_blacklisted() runs on MTC_CT {
+ var ConnHdlr vc_conn;
+ var ConnHdlrPars pars := f_ConnHdlrPars(4); /* idx: see create_test_subscribers.sh */
+ f_init();
+ vc_conn := f_start_handler(refers(f_TC_CheckQuipmentIdentity_imei_specific_supi_found_blacklisted), pars);
+ vc_conn.done;
+ f_shutdown();
+}
+
+/* 3GPP TS 29.511 5.2.2.2.2 Procedure using CheckEquipmentIdentity Operation */
+private function f_TC_CheckQuipmentIdentity_imei_specific_supi_found_greylisted() runs on ConnHdlr {
+ var template (value) EquipmentStatusParameters query;
+ query := ts_EquipmentStatusParameters(pei := ts_Pei_IMEI(g_pars.imei_str),
+ supi := ts_Supi_IMSI(g_pars.imsi_str));
+ f_n17_get_equipment_status(eq_status_param := query, status := GREYLISTED);
+ setverdict(pass);
+}
+testcase TC_CheckQuipmentIdentity_imei_specific_supi_found_greylisted() runs on MTC_CT {
+ var ConnHdlr vc_conn;
+ var ConnHdlrPars pars := f_ConnHdlrPars(5); /* idx: see create_test_subscribers.sh */
+ f_init();
+ vc_conn := f_start_handler(refers(f_TC_CheckQuipmentIdentity_imei_specific_supi_found_greylisted), pars);
+ vc_conn.done;
+ f_shutdown();
+}
+
+control {
+ execute( TC_CheckQuipmentIdentity_imei_not_found() );
+ execute( TC_CheckQuipmentIdentity_imei_generic_found_whitelisted() );
+ execute( TC_CheckQuipmentIdentity_imei_generic_found_blacklisted() );
+ execute( TC_CheckQuipmentIdentity_imei_generic_found_greylisted() );
+ execute( TC_CheckQuipmentIdentity_imei_specific_supi_found_whitelisted() );
+ execute( TC_CheckQuipmentIdentity_imei_specific_supi_found_blacklisted() );
+ execute( TC_CheckQuipmentIdentity_imei_specific_supi_found_greylisted() );
+}
+
+}
diff --git a/eir/README.md b/eir/README.md
new file mode 100644
index 0000000..fe75e29
--- /dev/null
+++ b/eir/README.md
@@ -0,0 +1,14 @@
+# EIR_Tests.ttcn
+
+* external interfaces
+ * N17: SBI (emulates AMF)
+
+{% dot eir_tests.svg
+digraph G {
+ rankdir=LR;
+ ATS [label="ATS\nEIR_Tests.ttcn"];
+ UDM [label="AMF\open5gs-eird",shape="box"];
+
+ ATS -> UDM [label="N17"];
+}
+%}
diff --git a/eir/create_test_subscribers.sh b/eir/create_test_subscribers.sh
new file mode 100755
index 0000000..ee0d6c6
--- /dev/null
+++ b/eir/create_test_subscribers.sh
@@ -0,0 +1,15 @@
+#!/bin/sh -ex
+DB_URI="mongodb://127.0.0.103/open5gs"
+DBCTL_CMD="open5gs-dbctl --db_uri=$DB_URI"
+
+# mongod needs some time to bootstrap...
+while ! mongosh --quiet $DB_URI</dev/null; do
+ sleep 1
+done
+
+$DBCTL_CMD eir add imei "490154203000000" "WHITELISTED" # "999700000000000" No IMSI
+$DBCTL_CMD eir add imei "490154203000001" "BLACKLISTED" # "999700000000001" No IMSI
+$DBCTL_CMD eir add imei "490154203000002" "GREYLISTED" # "999700000000002" No IMSI
+$DBCTL_CMD eir add imei "490154203000003" "WHITELISTED" "999700000000003"
+$DBCTL_CMD eir add imei "490154203000004" "BLACKLISTED" "999700000000004"
+$DBCTL_CMD eir add imei "490154203000005" "GREYLISTED" "999700000000005"
diff --git a/eir/expected-results.xml b/eir/expected-results.xml
new file mode 100644
index 0000000..6f0b1a0
--- /dev/null
+++ b/eir/expected-results.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0"?>
+<testsuite name='Titan' tests='7' failures='0' errors='0' skipped='0' inconc='0' time='MASKED'>
+ <testcase classname='EIR_Tests' name='TC_CheckQuipmentIdentity_imei_not_found' time='MASKED'/>
+ <testcase classname='EIR_Tests' name='TC_CheckQuipmentIdentity_imei_generic_found_whitelisted' time='MASKED'/>
+ <testcase classname='EIR_Tests' name='TC_CheckQuipmentIdentity_imei_generic_found_blacklisted' time='MASKED'/>
+ <testcase classname='EIR_Tests' name='TC_CheckQuipmentIdentity_imei_generic_found_greylisted' time='MASKED'/>
+ <testcase classname='EIR_Tests' name='TC_CheckQuipmentIdentity_imei_specific_supi_found_whitelisted' time='MASKED'/>
+ <testcase classname='EIR_Tests' name='TC_CheckQuipmentIdentity_imei_specific_supi_found_blacklisted' time='MASKED'/>
+ <testcase classname='EIR_Tests' name='TC_CheckQuipmentIdentity_imei_specific_supi_found_greylisted' time='MASKED'/>
+</testsuite>
diff --git a/eir/gen_links.sh b/eir/gen_links.sh
new file mode 100755
index 0000000..a6de4b8
--- /dev/null
+++ b/eir/gen_links.sh
@@ -0,0 +1,52 @@
+#!/bin/bash -e
+
+BASEDIR=../deps
+
+. ../_buildsystem/gen_links.inc.sh
+
+DIR=$BASEDIR/titan.Libraries.TCCUsefulFunctions/src
+FILES="TCCInterface_Functions.ttcn TCCConversion_Functions.ttcn TCCConversion.cc TCCInterface.cc TCCInterface_ip.h"
+FILES+=" TCCEncoding_Functions.ttcn TCCEncoding.cc " # GSM 7-bit coding
+gen_links $DIR $FILES
+
+DIR=$BASEDIR/titan.TestPorts.Common_Components.Socket-API/src
+FILES="Socket_API_Definitions.ttcn"
+gen_links $DIR $FILES
+
+# Required by MGCP and IPA
+DIR=$BASEDIR/titan.TestPorts.IPL4asp/src
+FILES="IPL4asp_Functions.ttcn IPL4asp_PT.cc IPL4asp_PT.hh IPL4asp_PortType.ttcn IPL4asp_Types.ttcn IPL4asp_discovery.cc IPL4asp_protocol_L234.hh"
+gen_links $DIR $FILES
+
+# Needed by HTTP_Adapter (Prometheus_Checker.ttcn metrics):
+DIR=$BASEDIR/titan.TestPorts.Common_Components.Abstract_Socket/src
+FILES="Abstract_Socket.cc Abstract_Socket.hh "
+gen_links $DIR $FILES
+
+# Needed by HTTP_Adapter (Prometheus_Checker.ttcn metrics):
+DIR=$BASEDIR/titan.TestPorts.HTTPmsg/src
+FILES="HTTPmsg_MessageLen.ttcn HTTPmsg_MessageLen_Function.cc HTTPmsg_PT.cc HTTPmsg_PT.hh HTTPmsg_PortType.ttcn HTTPmsg_Types.ttcn "
+gen_links $DIR $FILES
+
+# Needed by HTTP2_Adapter:
+DIR=$BASEDIR/titan.ProtocolModules.HTTP2/src
+FILES="HTTP2_EncDec.cc HTTP2_Types.ttcn"
+gen_links $DIR $FILES
+
+DIR=$BASEDIR/titan.ProtocolModules.JSON_v07_2006/src
+FILES="JSON_Generic_Null_Def.asn JSON_Generic.ttcn"
+gen_links $DIR $FILES
+
+DIR=$BASEDIR/osmo-ttcn3-openapi-generator/openapi-specs/3GPP_5GC_Rel19/ttcn3
+FILES="TS29511_N5g_eir_EquipmentIdentityCheck.ttcn "
+gen_links $DIR $FILES
+
+DIR=../library
+FILES="Misc_Helpers.ttcn General_Types.ttcn GSM_Types.ttcn Osmocom_Types.ttcn Native_Functions.ttcn Native_FunctionDefs.cc IPCP_Types.ttcn IPCP_Templates.ttcn "
+FILES+="SCTP_Templates.ttcn "
+FILES+="HTTP2_CodecPort.ttcn HTTP2_CodecPort_CtrlFunct.ttcn HTTP2_CodecPort_CtrlFunctDef.cc HTTP2_Templates.ttcn HTTP2_Functions.ttcn HTTP2_Msg.ttcn HTTP2_Adapter.ttcn HTTP2_Server_Emulation.ttcn "
+FILES+="HTTP_Adapter.ttcn Prometheus_Checker.ttcn "
+FILES+="TS29511_N5g_eir_EquipmentIdentityCheck_Templates.ttcn "
+gen_links $DIR $FILES
+
+gen_links_finish
diff --git a/eir/mongod.conf b/eir/mongod.conf
new file mode 100644
index 0000000..ff648f4
--- /dev/null
+++ b/eir/mongod.conf
@@ -0,0 +1,45 @@
+# mongod.conf
+
+# for documentation of all options, see:
+# http://docs.mongodb.org/manual/reference/configuration-options/
+
+# Where and how to store data.
+storage:
+ dbPath: db
+# journal:
+# enabled: true
+# engine:
+# mmapv1:
+# wiredTiger:
+
+# where to write logging data.
+# systemLog:
+# destination: file
+# logAppend: true
+# path: /data/mongod.log
+
+# network interfaces
+net:
+ port: 27017
+ bindIp: 127.0.0.103
+
+
+# how the process runs
+processManagement:
+ timeZoneInfo: /usr/share/zoneinfo
+
+#security:
+
+#operationProfiling:
+
+#replication:
+
+#sharding:
+
+## Enterprise-Only Options:
+
+#auditLog:
+
+#snmp:
+
+
diff --git a/eir/open5gs-eir.yaml b/eir/open5gs-eir.yaml
new file mode 100644
index 0000000..efbef3a
--- /dev/null
+++ b/eir/open5gs-eir.yaml
@@ -0,0 +1,18 @@
+db_uri: mongodb://127.0.0.103/open5gs
+logger:
+ level: debug
+
+global:
+ max:
+ ue: 1024
+
+eir:
+ sbi:
+ server:
+ - address: 127.0.0.21
+ port: 7777
+ client:
+# nrf:
+# - uri: http://127.0.0.10:7777
+ scp:
+ - uri: http://127.0.0.200:7777
diff --git a/eir/regen_makefile.sh b/eir/regen_makefile.sh
new file mode 100755
index 0000000..9ed4246
--- /dev/null
+++ b/eir/regen_makefile.sh
@@ -0,0 +1,23 @@
+#!/bin/sh -e
+
+NAME=EIR_Tests
+
+FILES="
+ *.asn
+ *.ttcn
+ Abstract_Socket.cc
+ HTTPmsg_MessageLen_Function.cc
+ HTTPmsg_PT.cc
+ HTTP2_EncDec.cc
+ HTTP2_CodecPort_CtrlFunctDef.cc
+ IPL4asp_PT.cc
+ IPL4asp_discovery.cc
+ Native_FunctionDefs.cc
+ TCCConversion.cc
+ TCCEncoding.cc
+ TCCInterface.cc
+"
+
+. ../_buildsystem/regen_makefile.inc.sh
+
+sed -i -e 's/^LINUX_LIBS = -lxml2 -lsctp/LINUX_LIBS = -lxml2 -lsctp -lgnutls/' Makefile
diff --git a/eir/testenv.cfg b/eir/testenv.cfg
new file mode 100644
index 0000000..6a41e9d
--- /dev/null
+++ b/eir/testenv.cfg
@@ -0,0 +1,20 @@
+[testsuite]
+program=EIR_Tests
+config=EIR_Tests.cfg
+
+[db]
+prepare=mkdir db
+clean=rm -rf db
+program=mongod --config mongod.conf
+setup=create_test_subscribers.sh
+copy=mongod.conf
+make=no
+package=no
+
+
+[eir]
+program=open5gs-eird -c open5gs-eir.yaml
+make=open5gs
+package=open5gs-eir
+copy=open5gs-eir.yaml
+
diff --git a/eir/testsrcdir.cfg b/eir/testsrcdir.cfg
new file mode 100644
index 0000000..7f19289
--- /dev/null
+++ b/eir/testsrcdir.cfg
@@ -0,0 +1,2 @@
+[testsrcdir]
+max_jobs_per_gb_ram=0.3
diff --git a/library/TS29511_N5g_eir_EquipmentIdentityCheck_Templates.ttcn b/library/TS29511_N5g_eir_EquipmentIdentityCheck_Templates.ttcn
new file mode 100644
index 0000000..52c6230
--- /dev/null
+++ b/library/TS29511_N5g_eir_EquipmentIdentityCheck_Templates.ttcn
@@ -0,0 +1,71 @@
+module TS29511_N5g_eir_EquipmentIdentityCheck_Templates {
+
+import from TS29511_N5g_eir_EquipmentIdentityCheck all;
+
+const charstring c_N5g_eir_eic_path_api_prefix := "/n5g-eir-eic/v1";
+
+/* 6.1.3.2 Resource: equipmentStatus */
+const charstring c_N5g_eir_eic_path_equipment_status
+:= c_N5g_eir_eic_path_api_prefix & "/equipment-status";
+
+/* Table 6.1.3.2.3.1-1: URI query parameters supported by the GET method on this resource */
+type set EquipmentStatusParameters {
+ Pei pei,
+ Supi supi optional,
+ Gpsi gpsi optional,
+ SupportedFeatures supported_features optional
+};
+
+template (value) EquipmentStatusParameters
+ts_EquipmentStatusParameters(template (value) Pei pei,
+ template (omit) Supi supi := omit,
+ template (omit) Gpsi gpsi := omit,
+ template (omit) SupportedFeatures supported_features := omit) := {
+ pei := pei,
+ supi := supi,
+ gpsi := gpsi,
+ supported_features := supported_features
+}
+
+function f_enc_EquipmentStatusParameters(EquipmentStatusParameters val) return charstring
+{
+ var charstring enc := "?pei=" & val.pei;
+ if (ispresent(val.supi)) {
+ enc := enc & "&supi=" & val.supi;
+ }
+ if (ispresent(val.gpsi)) {
+ enc := enc & "&gpsi=" & val.gpsi;
+ }
+ if (ispresent(val.supported_features)) {
+ enc := enc & "&supported-features=" & val.supported_features;
+ }
+ return enc;
+}
+
+template (present) EirResponseData
+tr_EirResponseData(template (present) EquipmentStatus status := ?) := {
+ status := status
+}
+
+template (value) Pei
+ts_Pei_IMEI(template (value) charstring imei)
+:= "imei-" & valueof(imei);
+
+template (value) Pei
+ts_Pei_IMEISV(template (value) charstring imei)
+:= "imeisv-" & valueof(imei);
+
+template (value) Pei
+ts_Pei_MAC(template (value) charstring mac,
+ template (value) charstring untrusted := "-untrusted")
+:= "mac-" & valueof(mac) & valueof(untrusted);
+
+template (value) Pei
+ts_Pei_EUI(template (value) charstring eui)
+:= "eui-" & valueof(eui);
+
+template (value) Pei
+ts_Supi_IMSI(template (value) charstring imsi)
+:= "imsi-" & valueof(imsi);
+
+}
To view, visit change 44063. To unsubscribe, or for help writing mail filters, visit settings.